topic Re: creating data set in SAS Programming

creating data set

deleted_user — Thu, 04 Jun 2009 05:32:26 GMT

Hi ,

Any one can help me to resolve this issue. i want to create new variables for same value in A variable.

DATA SMP;
INPUT A B C;
DATALINES;
1 20 30
1 32 40
1 45 60
2 28 40
2 30 40
;
i have tried in the following way but i dint get the result dataset
DATA SMP1;
ARRAY S(3) A1 A2 A3;
ARRAY SB(3) B1 B2 B3;
ARRAY SC(3) C1 C2 C3;
SET SMP;
BY A;
IF FIRST.A THEN DO I=1 TO 3;
S(I)=A;
SB(I)=B;
SC(I)=C;
END;
RUN;

out put is:

OUTPUT;
A B C A1 B1 C1 A2 B2 C2
1 20 30 1 32 40 1 45 60
2 28 40 2 30 40 . . .

Thanks in advance for response

Thanks
Slone

Re: creating data set

LinusH — Thu, 04 Jun 2009 07:36:50 GMT

This seems like a transpose to me.
Have a look at PROC TRANSPOSE.
If you want to do it in a data step, you might want to use RETAIN and explicit OUTPUT techniques instead.

/Linus

Re: creating data set

deleted_user — Thu, 04 Jun 2009 08:58:26 GMT

Hi Linus,

Thank's for response,
i can create this by using Transpose and then merge these individual datasets , but is there any possibility, like hold that paritcular observation and check across the same group observations in a single data step.

Re: creating data set

LinusH — Thu, 04 Jun 2009 10:29:47 GMT

I am absolutely no array king, but here's a suggestion. I didn't bother to include A1-A3, since I couldn't understand what use you have for them, since A is the key...?

DATA SMP1;
SET SMP;
array bb(3) b1-b3;
array cc(3) c1-c3;
retain b1 b2 b3 c1 c2 c3 n;
BY A;
if first.a then do;
n = 1;
do i=1 to dim(bb);
bb(i) = .;
cc(i) = .;
end;
end;
bb(n) = b;
cc(n) = c;
put _all_;
IF LAST.A THEN output;
n+1;
RUN;

Re: creating data set

deleted_user — Thu, 04 Jun 2009 11:16:27 GMT

Hi Linus,

Thank u very much, This is what i am looking for.

Thanks
Slone