topic Re: reading in more data in SAS Programming

reading in more data

cj9000 — Fri, 05 May 2017 06:08:50 GMT

HI again.

I added another column and data and formatted the input statement as instructed. It seems to have blown up though. Here's the code: Thanks in advance:

data widepe ;
input subjectnumberstr: $9. visitmnemonic: $9. pegenap_c: & $24. peheent_c: & $24.;
datalines;
0100-1204 screening Abnormal, please specify Abnormal, please specify
0100-1204 eos/et Normal normal
0100-1205 Screening Normal normal
0100-1205 EOS/ET Normal Abnormal, please specify
;
run;
proc print data = widepe; run;

SAS Output

Obs	subjectnumberstr	visitmnemonic	pegenap_c	peheent_c
1	0100-1204	screening	Abnormal, please specify	0100-1204 eos/et Normal
2	0100-1205	Screening	Normal normal	0100-1205 EOS/ET Normal

Re: reading in more data

Kurt_Bremser — Fri, 05 May 2017 06:36:37 GMT

Remove the ampersands.

data widepe ;
input subjectnumberstr: $9. visitmnemonic: $9. pegenap_c:  $24. peheent_c:  $24.;
datalines;
0100-1204 screening Abnormal, please specify Abnormal, please specify
0100-1204 eos/et Normal normal
0100-1205 Screening Normal normal
0100-1205 EOS/ET Normal Abnormal, please specify
;
run;
proc print data = widepe; run;

works.

Re: reading in more data

cj9000 — Fri, 05 May 2017 11:13:00 GMT

Hmmm Thanks Kurt but when i ran the code I got:

Obs subjectnumberstr visitmnemonic pegenap_c peheent_c
1 0100-1204 screening Abnormal, please
2 0100-1204 eos/et Normal normal
3 0100-1205 Screening Normal normal
4 0100-1205 EOS/ET Normal Abnormal,
So then i tried increasing the lengths of the last two variables but got
the same results

##- Please type your reply above this line. Simple formatting, no
attachments. -##

Re: reading in more data

cj9000 — Fri, 05 May 2017 11:15:24 GMT

This might display better, this is what I got.

SAS Output

Obs	subjectnumberstr	visitmnemonic	pegenap_c	peheent_c
1	0100-1204	screening	Abnormal,	please
2	0100-1204	eos/et	Normal	normal
3	0100-1205	Screening	Normal	normal
4	0100-1205	EOS/ET	Normal	Abnormal,

Re: reading in more data

Kurt_Bremser — Fri, 05 May 2017 11:30:58 GMT

Oh, totally missed the blanks in the data.

To read variable length strings that contain blanks, you need either a delimiter in the input data, or you have to enclose the strings in quotes. Then you can use the dsd option:

data widepe;
infile cards dlm="|" truncover;
input subjectnumberstr: $9. visitmnemonic: $9. pegenap_c:  $24. peheent_c:  $24.;
datalines;
0100-1204|screening|Abnormal, please specify|Abnormal, please specify
0100-1204|eos/et|Normal|normal
0100-1205|Screening|Normal|normal
0100-1205|EOS/ET|Normal|Abnormal, please specify
;
run;

proc print data=widepe noobs;
run;

data widepe;
infile cards dlm=" " dsd truncover;
input subjectnumberstr: $9. visitmnemonic: $9. pegenap_c:  $24. peheent_c:  $24.;
datalines;
0100-1204 "screening" "Abnormal, please specify" "Abnormal, please specify"
0100-1204 "eos/et" "Normal" "normal"
0100-1205 "Screening" "Normal" "normal"
0100-1205 "EOS/ET" "Normal" "Abnormal, please specify"
;
run;

proc print data=widepe noobs;
run;

Results:

subjectnumberstr    visitmnemonic    pegenap_c                   peheent_c

   0100-1204          screening      Abnormal, please specify    Abnormal, please specify
   0100-1204          eos/et         Normal                      normal                  
   0100-1205          Screening      Normal                      normal                  
   0100-1205          EOS/ET         Normal                      Abnormal, please specify

subjectnumberstr    visitmnemonic    pegenap_c                   peheent_c

   0100-1204          screening      Abnormal, please specify    Abnormal, please specify
   0100-1204          eos/et         Normal                      normal                  
   0100-1205          Screening      Normal                      normal                  
   0100-1205          EOS/ET         Normal                      Abnormal, please specify

Re: reading in more data

cj9000 — Fri, 05 May 2017 11:39:33 GMT

Thank you Kurt for the solution, it works great. But I thought the ampersand modifier allowed for sas to read blanks within the variable length but I guess not.

Re: reading in more data

Kurt_Bremser — Fri, 05 May 2017 11:46:38 GMT

@cj9000 wrote:

Thank you Kurt for the solution, it works great. But I thought the ampersand modifier allowed for sas to read blanks within the variable length but I guess not.

You are referring to this:

&

indicates that a character value can have one or more single embedded blanks. This format modifier reads the value from the next non-blank column until the pointer reaches two consecutive blanks, the defined length of the variable, or the end of the input line, whichever comes first.

(underline by me)

For that to work, you would have needed two blanks in succession as delimiters.

Re: reading in more data

cj9000 — Fri, 05 May 2017 12:03:43 GMT

Oh I see. Okay well thank you Kurt.