topic Re: How to inherit the value from previous value in SAS Programming

How to inherit the value from previous value

lionking19063 — Tue, 02 May 2017 14:45:54 GMT

Hello,

I wonder if someone could help me? I try to make a table which inherits the group information from previous value. Thank you.

Input:

group	id
group1	1
	2
	3
group2	4
	5
group3	6

Ouput:

group	id
group1	1
group2	2
group3	3
group2	4
group3	5
group3	6

Re: How to inherit the value from previous value

art297 — Tue, 02 May 2017 14:59:13 GMT

Either I don't understand or your example wasn't right. Are you trying to do the following:

data have;
  infile cards dlm=',' truncover;
  input group $ id;
  cards;
group1,1
 ,2
 ,3
group2,4
 ,5
group3,6
;

proc sort data=have;
  by descending id;
run;

data want (drop=hold);
  set have;
  retain hold;
  if not missing(group) then hold=group;
  else group=hold;
run;

Art, CEO, AnalystFinder.com

Re: How to inherit the value from previous value

lionking19063 — Tue, 02 May 2017 15:21:26 GMT

Thank you so much. It worked.

Re: How to inherit the value from previous value

Tom — Tue, 02 May 2017 16:36:28 GMT

You should just be able to use a retained variable.

data want ;
  set have;
  hold = coalescec(group,hold);
  group = coalescec(group,hold);
  retain hold;
  drop hold;
run;

Unfortunately SAS sees the first reference to HOLD as being the reference inside the function call instead of the result of assignment statement and defaults HOLD to numeric. So you need to add a LENGTH statement to define HOLD.

Or you could use this trick to make a copy of GROUP with the name of HOLD. That way you do not need to know the length of GROUP in advance. It will also mark the variable as retained since it is coming from a dataset, so the RETAIN statement is not needed.

data want ;
   set have have (obs=0 rename=(group=hold));
   hold = coalescec(group,hold);
   group = coalescec(group,hold);
   drop hold;
run;