topic Re: proc transpose output in SAS Programming

proc transpose output

echoli — Mon, 01 May 2017 16:31:40 GMT

Hi All,

I have an output like below:

group	Coefficient	pvalue
Toddler	0.5	0.003
Young	0.7	0.005
Child	0.6	0.21

I want to transpose the ouput like this:

Toddler_Coeff	Toddler_Pvalue	Young_Coeff	Young_Pvalue	Child_Coeff	Child_Pvalue
0.5	0.003	0.7	0.005	0.6	0.21

But when I use proc transpose, the output like this:

	Toddler	Young	Child
Coefficient	0.5	0.7	0.6
pvalue	0.003	0.005	0.21

here is my part code:

proc transpose data=final_1 out=final_1 ;
var coefficient pvalue;
id group;
run;

Any way to help?

Thanks,

Re: proc transpose output

Astounding — Mon, 01 May 2017 17:03:55 GMT

PROC TRANSPOSE could do something like that. It would take a few steps, and generate different names (such as Coeff_Young instead of Young_Coeff).

For such a small data set, I would suggest coding it yourself. For example:

data want;

do until (done);

set have end=done;

if group='Toddler' then do; Toddler_Coeff = coefficient; Toddler_Pvalue = pvalue; end;

else if group='Young' then do; Young_Coeff=coefficient; Young_Pvalue = pvalue; end;

else do; Child_Coeff = coefficient; Child_Pvalue = pvalue; end;

end;

drop group coefficient pvalue;

run;

Re: proc transpose output

Tom — Mon, 01 May 2017 17:04:32 GMT

Use two steps.

proc sort data=have; by group ; run;
proc transpose data=have out=middle ;
 by group;
 var Coefficient pvalue ;
run;
proc transpose data=middle out=want delimiter=_;
  id group _name_;
  var col1;
run;

Re: proc transpose output

echoli — Mon, 01 May 2017 18:30:55 GMT

Thanks, that really helps!!!

Re: proc transpose output

echoli — Mon, 01 May 2017 18:31:27 GMT

Thanks, that helps!

Re: proc transpose output

Astounding — Tue, 02 May 2017 16:04:13 GMT

Coincidence? I actually had occasion to use this technique today. Made me look like a magician. Awesome!