topic Re: auto dates in SAS Programming

auto dates

tparvaiz — Tue, 25 Apr 2017 22:28:27 GMT

in our sas program we have dates thta are hard coded, something like this

%let YYYYMM = 201704;
%let date1 = '01Apr2017'd;
%let date2 = '01May2017'd;

everythime we run a report, have to manually change them. can yo uplease advise how to automate these values.

YYYMM is the previous month and year

date1 is the first date of the previous month

date2 is the first daty of the current month

thanks in advance

Re: auto dates

ChrisNZ — Tue, 25 Apr 2017 22:49:32 GMT

Like this?

%let YYYYMM =         %sysfunc(putn(%sysfunc(intnx(month,%sysfunc(today()),-1)),yymmn6.));
%let date1  = %str(%')%sysfunc(putn(%sysfunc(intnx(month,%sysfunc(today()),-1)),date9.))%str(%')d;
%let date2  = %str(%')%sysfunc(putn(%sysfunc(intnx(month,%sysfunc(today()), 0)),date9.))%str(%')d;

Re: auto dates

ballardw — Tue, 25 Apr 2017 23:05:46 GMT

data _null_;
   call symputx('YYYMM',put(intnx('month',today(),-1),yymmn6.));
   call symputx('date1',intnx('month',today(),-1,'b'));
   call symputx('date2',intnx('month',today(),0,'b'));
run;

Which is much easier on my eyes than nested %sysfunc.

Yes, this does not have '01Apr2017'd but the numeric value that the date resolves to. Unless you are actually putting date1 and date2 into text output such as a title then the numeric will work just fine.