topic Re: Data Set options in SAS Programming

Data Set options

Melvin_Sas — Thu, 20 Apr 2017 19:16:17 GMT

I like to copy data from one dataset to another example from dataset B to dataset A but if there are 0 zero records in dataset B it should not overwrite dataset A. Is there any where clause option I can add in the set option to check this. Thanks

Data A;

set B;

run;

Re: Data Set options

Astounding — Thu, 20 Apr 2017 19:35:40 GMT

You might be able to piece something together that works some of the time, using only a DATA step. But the best solution would use macro language. For example:

%macro replace (in=, out=);

%local any_obs;

%let any_obs=N;

data _null_;

set &in;

call symput('any_obs', 'Y');

stop;

run;

%if &any_obs=Y %then %do;

data &out;

set &in;

run;

%end;

%mend replace;

%replace (in=B, out=A)

Re: Data Set options

Haikuo — Thu, 20 Apr 2017 21:01:18 GMT

For your purpose, you could simply do:

data A;
	if n>0 then
		set B nobs=n;
	else set A;
run;

However, there are things you need to be aware of:

1. All variables will show up regardless the source dataset is copied or not, only their contents will come in missing if not copied.

2. When B is empty, instead of doing nothing, A is copied again.

Re: Data Set options

Tom — Thu, 20 Apr 2017 22:05:07 GMT

Here is a method you can use. The first data _null_ step will test if there are any observations in B and set a macro varible to either CANCEL or spaces. That way you can conditionally add the CANCEL keyword to the second data step's RUN statement.

data _null_;
  call symputx('cancel',ifc(eof,'cancel',''));
  stop;
  set b end=eof;
run;
data a;
  set b;
run &cancel;

Note that you will get a message in the log if you cancel the second step.

1304  data a;
1305    set b;
1306  run &cancel;

WARNING: DATA step not executed at user's request.

Re: Data Set options

ChrisNZ — Fri, 21 Apr 2017 02:57:03 GMT

I would do this thus:

data _null_;

set B (obs=1);

call execute('proc datasets lib=WORK noprint; age B A; run;');

run;

The second statement is only executed if an observation can be read in B.

Renaming with proc datasets is much faster than copying a whole data set all over again, and conserves whatever attributes table B had (sortedby flag, index, compression, etc).

Re: Data Set options

Ksharp — Fri, 21 Apr 2017 04:04:50 GMT




data b;
 set sashelp.class;
 stop;
run;

data a;
 set sashelp.class;
run;

data a(repempty=no);
 set b;
run;