topic Re: How can I convert a table with one row to a table with multiple rows? in SAS Programming

How can I convert a table with one row to a table with multiple rows?

Jonathanzz — Wed, 12 Apr 2017 16:59:59 GMT

Can I convert the data in a table with one row to a table with multiple rows? What are their coding?

Original table:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16

Table that I want:

1 2 3 4

5 6 7 8

9 10 11 12

13 14 15 16

Re: How can I convert a table with one row to a table with multiple rows?

art297 — Wed, 12 Apr 2017 17:41:19 GMT

data have;
  input var1-var4 @@;
  cards;
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16
;

Art, CEO, AnalystFinder.com

Re: How can I convert a table with one row to a table with multiple rows?

Reeza — Wed, 12 Apr 2017 17:45:16 GMT

In this case an Array is probably your best bet, with an explicit OUTPUT statement. Here's a quick example with two loops.

data want;
set have;

array vals(*) val1-val16;
array new(*) new1-new4;

do i=1 to 4;

    do j=1 to 4;
         new(j) = vals(j*i);
    end;

output;

end;
run;

@Jonathanzz wrote:

Can I convert the data in a table with one row to a table with multiple rows? What are their coding?

Original table:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16

Table that I want:

1 2 3 4

5 6 7 8

9 10 11 12

13 14 15 16

Re: How can I convert a table with one row to a table with multiple rows?

Ksharp — Thu, 13 Apr 2017 13:13:20 GMT

It is very easy for IML code.

data have;
  input var1-var4 @@;
  cards;
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16
;

proc iml;
use have;
read all var _all_ into x;
close;

want=shape(x,0,4);

create want from want;
append from want;
close;
quit;

Re: How can I convert a table with one row to a table with multiple rows?

Jonathanzz — Thu, 13 Apr 2017 17:07:06 GMT

Thanks a lot!

Re: How can I convert a table with one row to a table with multiple rows?

ilikesas — Fri, 14 Apr 2017 00:52:53 GMT

I guess that one way for this approach would be:

data want (keep = new1-new4);
set have;
array vals(*) var1-var16;
array new(*) new1-new4;

do j = 1 to floor(dim(vals)/4);
  do i = 1 to 4;
    new(i) = vals((j-1)*4 + i);
  end;
  output;
end;
run;

Re: How can I convert a table with one row to a table with multiple rows?

CiCi — Fri, 14 Apr 2017 06:27:14 GMT

I would probably

1. add a new observation with values like 1,2,3,4,1,2,3,4,1,2,3,4,....

2. use Proc Transpose

When your dataset is large, this can be super efficiant by avoiding loops.