topic Re: how to select only required obs when concatenating datassets in SAS Programming

how to select only required obs when concatenating datassets

knveraraju91 — Tue, 11 Apr 2017 15:57:17 GMT

Dear,

I need to concatenate the datasets "one and two" to get last date from data two.

In data two there are more subjects than data one. I need to have in my output only subjects that are in dataone. Please help . Thank you

data one;
input id date date9.
datalines;
1 05OCT2015
2 06OCT2015
3 07OCT2015
;
data two;
input id date date9.;
datalines;
1 05DEC2015
2 06DEC2015
3 07DEC2015 
4 08DEC2015
;

code:

data three;

set one two;

run;

output needed;

id date

1 05OCT2015
2 06OCT2015
3 07OCT2015

1 05DEC2015
2 06DEC2015
3 07DEC2015

Re: how to select only required obs when concatenating datassets

PaigeMiller — Tue, 11 Apr 2017 16:13:29 GMT

UNTESTED CODE

data want;
    merge one(in=in1 rename=(date=date1)) two(in=in2 rename=(date=date2));
    by id;
    if in1 and in2;
run;

Re: how to select only required obs when concatenating datassets

novinosrin — Tue, 11 Apr 2017 16:15:07 GMT

A silly solution, forgive me but fun:

data one;
input id date :date9.;
format date date9.;
datalines;
1 05OCT2015
2 06OCT2015
3 07OCT2015
;
data two;
input id date :date9.;
format date date9.;
datalines;
1 05DEC2015
2 06DEC2015
3 07DEC2015
4 08DEC2015
;
data temp;
merge one(in=a) two(in=b);
by id;
if a and b;
run;
data want;
set one temp;
run;

Re: how to select only required obs when concatenating datassets

knveraraju91 — Tue, 11 Apr 2017 16:23:27 GMT

Thank you for the support.

But I need to concatenate the datasets, not merging. Thank you

Re: how to select only required obs when concatenating datassets

PaigeMiller — Tue, 11 Apr 2017 17:15:34 GMT

But I need to concatenate the datasets, not merging. Thank you

In that case @novinosrin has provided the solution.

Re: how to select only required obs when concatenating datassets

data_null__ — Tue, 11 Apr 2017 17:35:43 GMT

data three;
   set one(in=in1) two(in=in2);
   by id;
   if first.id and in2 then delete;
   format date date9.;
   run;

Re: how to select only required obs when concatenating datassets

Ksharp — Wed, 12 Apr 2017 13:46:13 GMT

Assuming there are not duplicated ID in both tables.



data one;
input id date :date9.;
format date date9.;
datalines;
1 05OCT2015
2 06OCT2015
3 07OCT2015
;
data two;
input id date :date9.;
format date date9.;
datalines;
1 05DEC2015
2 06DEC2015
3 07DEC2015
4 08DEC2015
;
data want;
 set one two;
 by id;
 if first.id and last.id then delete;
run;