topic Re: How to round values in stat procedures in SAS Programming

How to round values in stat procedures

louis_usa — Sat, 08 Apr 2017 16:00:05 GMT

I treied to make all my statistical outputs to round 2 decimals. For example, here is code:

ods rtf file='c:\SAS\MeanOutput.rtf';
proc means data = sashelp.class nmiss N min max mean std;
var _numeric_ ;
format _numeric_ comma10.2;
run;
ods rtf close;

where the format statement doen't work. Any help or suggestion would be appreciated. Thank you.

Louis

Re: How to round values in stat procedures

PeterClemmensen — Sat, 08 Apr 2017 16:27:50 GMT

Use the maxdec option like this 🙂

proc means data = sashelp.class nmiss N min max mean std maxdec = 2;
var _numeric_ ;
run;

Re: How to round values in stat procedures

louis_usa — Sat, 08 Apr 2017 16:34:30 GMT

It worked like a charm. Thank you so much!

Re: How to round values in stat procedures

art297 — Sat, 08 Apr 2017 16:56:59 GMT

You already got a satisfactory answer, but that only changed the decimal places. It didn't apply the format you wanted (i.e. comma12.2).

If you need to change the formats for proc means, you can do that using proc template. e.g.:

ods path(prepend) work.templat(update);
proc template;
 edit base.summary;
  edit mean;
   format=comma12.2;
  end;
  edit sum;
   format=comma12.2;
  end;
  edit min;
   format=comma12.2;
  end;
  edit max;
   format=comma12.2;
  end;
  edit stddev;
   format=comma12.2;
  end;
 end;
run;

ods rtf file='/folders/myfolders/MeanOutput.rtf';
proc means data = sashelp.class nmiss N min max mean std;
  var _numeric_ ;
run;
ods rtf close;

proc template;
 delete base.summary;
run;

Art, CEO, AnalystFinder.com

Re: How to round values in stat procedures

louis_usa — Sat, 08 Apr 2017 17:06:23 GMT

Correct, I'm more interested in the change of the display. But thank you so much for showing me alternative way doing the format.