topic Re: Remplace missing value in SAS Programming

Remplace missing value

John4 — Thu, 06 Apr 2017 07:51:57 GMT

hello,

I have a large data set, look like this :

data mydata;
input id month mark last;
cards;
1 4 14.5 28
1 1 . .
1 3 . .
2 7 . .
;
run;

and I want to remplace all missing value by 14.5 and 28, I mean like this

ID month mark   last
1   4        14.5    28
1   5        14.5    28
1   1        14.5    28
1   3        14.5    28
2   7    14.5    28

Thank you

Re: Remplace missing value

PeterClemmensen — Thu, 06 Apr 2017 08:13:56 GMT

Like this?

data mydata;
input id month mark last;
cards;
1 4 14.5 28
1 1 . .
1 3 . .
2 7 . .
;
run;

data want;
	set mydata;
	if missing(mark) then mark=14.5;
	if missing(last) then last = 28;
run;

Re: Remplace missing value

John4 — Thu, 06 Apr 2017 08:18:06 GMT

Yes but since I have a large data set, I want to do it automatically

Re: Remplace missing value

PeterClemmensen — Thu, 06 Apr 2017 08:23:22 GMT

ok, with automatically, I take it that you mean that you always have the nonmissing value in the first observation? 🙂

data want;
	set mydata;
	if _N_ = 1 then do;
		temp_mark = mark;
		temp_last = last;
		retain temp_mark temp_last;
	end;
	if missing(mark) then mark=temp_mark;
	if missing(last) then last = temp_last;

	drop temp_mark temp_last;
run;

Re: Remplace missing value

John4 — Thu, 06 Apr 2017 08:44:16 GMT

Yes

Re: Remplace missing value

Ksharp — Thu, 06 Apr 2017 13:03:16 GMT

data mydata;
input id month mark last;
cards;
1 4 14.5 28
1 1 . .
1 3 . .
2 7 . .
;
run;

data want;
	set mydata(drop= mark last);
 if _n_=1 then set mydata(keep= mark last obs=1);
run;