topic Re: Macro Do loop - Skip a section when value fail a test in SAS Programming

Macro Do loop - Skip a section when value fail a test

hhchenfx — Wed, 29 Mar 2017 04:10:18 GMT

Hi,

My Macro has 2 sections. At the end of section 1, I get a mean value for variable, say xyz. If this mean is less than 10, I want SAS skip section 2 to move on a new loop.

Can you please help me with that?

Thank you so much.

HHC

%macro comp;
%local i j;
%do i=1 %to 100;
  %do j=1 %to 100;
		
	*PART 1: A lot of code	;

			proc means data=abc;
			var xyz;
			output out=check_value
			mean=mean_xyz;
			run;
	
	
			IF mean_xyz<10 THEN SKIP THE PART2 Code below

	*PART 2: A lot of code	;
		

%end;
%end;
%mend;

Re: Macro Do loop - Skip a section when value fail a test

LinusH — Wed, 29 Mar 2017 04:23:58 GMT

You probably need the conditional logic from %if.

To be able to do so, you need the mean_xyz as a macro variable, something like:

data _null_;
   set check_value;
   call symputx('MEAN_XYZ',mean_xyz);
run;

Re: Macro Do loop - Skip a section when value fail a test

ArtC — Wed, 29 Mar 2017 05:51:13 GMT

@hhchenfxI have added the DATA step suggested by @LinusH and a macro %IF.

%macro comp;
%local i j;
%do i=1 %to 100;
  %do j=1 %to 100;
		
	*PART 1: A lot of code	;
	proc means data=abc;
			var xyz;
			output out=check_value
			mean=mean_xyz;
			run;
	data _null_;
      set check_value;
      call symputx('MEAN_XYZ',mean_xyz);
      run;
	
	%IF %sysevalf(&mean_xyz>=10) %THEN %do;

	*PART 2: A lot of code	;
	%end;	

%end;
%end;
%mend comp;

Notice that in the %IF the %SYSEVALF is used. This is important because the mean (&MEAN_XYZ) will probably not be an integer. Non-integers would cause an alphabetic comparison (10<9. = true). I also reversed the comparison logic so that i could use a %DO block. There is also a %GOTO (much like the DATA step GOTO), but i am not a fan of it.

Re: Macro Do loop - Skip a section when value fail a test

hhchenfx — Thu, 30 Mar 2017 22:02:55 GMT

It is so great.
Thank you so much for your help.
HHC