topic Re: Hoiw to get variable from values in SAS? in SAS Programming

Hoiw to get variable from values in SAS?

contact2anil — Wed, 22 Mar 2017 18:03:04 GMT

Suppose we hv below data set..
I want to get max month from each obersvations in new variable.
like from 1st obs Mar and in 2nd obs Apr..

data year;
input jan feb mar apr jun;
datalines;
100 234 340 111 231
111 212 213 314 123
run;

By using below code we can calcuate maximum value

data aaa;
set year;
top=max(jan,feb,mar,apr,jun);
run;

Output:
Obs    jan    feb    mar    apr    jun    top
1     100    234    340    111    231    340
2     111    212    213    314    123    314

But i want to find variable which max value??

Please suugest solution?

Re: Hoiw to get variable from values in SAS?

art297 — Wed, 22 Mar 2017 18:08:51 GMT

data want;
  input jan feb mar apr jun;
  array list(*) jan--jun;
  top=max(of list(*));
  topvar = vname(list[whichn(max(of list[*]), of list[*])]);
  datalines;
100 234 340 111 231
111 212 213 314 123
;

Art, CEO, AnalystFinder.com

Re: Hoiw to get variable from values in SAS?

contact2anil — Thu, 23 Mar 2017 06:21:55 GMT

Hi Sir,

I am getting below error .. please check.

91   data want;
92     input jan feb mar apr jun;
93     array list(*) jan--jun ;
94     top=max(of list(*));
95     topvar = vname(list[whichn(max(of list[*]), of list[*])]);
                           ------
                           68
ERROR 68-185: The function WHICHN is unknown, or cannot be accessed.

96     datalines;

NOTE: The SAS System stopped processing this step because of errors.
WARNING: The data set WORK.WANT may be incomplete. When this step was stopped there were 0
         observations and 7 variables.
WARNING: Data set WORK.WANT was not replaced because this step was stopped.
NOTE: DATA statement used (Total process time):
      real time           0.01 seconds
      cpu time            0.01 seconds

Re: Hoiw to get variable from values in SAS?

Patrick — Thu, 23 Mar 2017 08:31:22 GMT

You're obviously using an old SAS version where function WHICHN() hasn't been implemented yet.

Which SAS version are you using?

Re: Hoiw to get variable from values in SAS?

contact2anil — Thu, 23 Mar 2017 08:59:54 GMT

Ok Thanks Patrick. It may be.
I am using SAS 9.0.

Re: Hoiw to get variable from values in SAS?

Patrick — Thu, 23 Mar 2017 09:11:49 GMT

I'm not aware of a commercial SAS 9.0 version. Here are the commercial versions: http://support.sas.com/techsup/support.html

In case you're using SAS "at home" for educational purposes: Download the free of charge non-commercial version and things will work in a modern environment. https://www.sas.com/en_au/software/university-edition.html

Please execute:

proc setinit; 
run;

Then consult the SAS log and tell us which SAS version you see there.

Re: Hoiw to get variable from values in SAS?

art297 — Thu, 23 Mar 2017 13:44:48 GMT

Since you don't have the whichn function, you can simply change that code to use a do loop to identify the corrrect variable:

data want;
  input jan feb mar apr jun;
  array list(*) jan--jun;
  top=max(of list(*));
/*  topvar = vname(list[whichn(max(of list[*]), of list[*])]);*/
  do i=1 to dim(list);
    if list(i) eq max(of list[*]) then do;
      topvar=vname(list[i]);
      return;
    end;
  end;
  datalines;
100 234 340 111 231
111 212 213 314 123
;

Art, CEO, AnalystFinder.com

Re: Hoiw to get variable from values in SAS?

contact2anil — Thu, 23 Mar 2017 18:18:53 GMT

Thanks Sir..

I got solution, This code is working fine.:)