topic Update Existing Format Value in SAS Programming

Update Existing Format Value

Sanket — Fri, 17 Mar 2017 12:28:13 GMT

Hi All,

I want to update existing format.

i tried

proc format library = work.formats

cntlout = cntlout;

run;

Now i want to update value for the existing format.

Format name :- FMT1

Old Value - ' OLDNAME' to New Value - ' NEWNAME'

so next time it should pickup NEWNAME so how to update existing format FMT1 Value ?

Please advise.

Thank you,

Sanket

Re: Update Existing Format Value

RW9 — Fri, 17 Mar 2017 12:54:16 GMT

Post test datas in the form of a datastep if you want exact answers. This is just the theory - use cntlout to get a dataset as you have done, updated that dataset as you want, then cntlin in proc format to read the dataset back in.

Re: Update Existing Format Value

Kurt_Bremser — Fri, 17 Mar 2017 13:10:29 GMT

@Sanket wrote:

Hi All,

I want to update existing format.

i tried

proc format library = work.formats

cntlout = cntlout;

run;

Now i want to update value for the existing format.

Format name :- FMT1

Old Value - ' OLDNAME' to New Value - ' NEWNAME'

so next time it should pickup NEWNAME so how to update existing format FMT1 Value ?

Please advise.

Thank you,

Sanket

You created a new dataset that describes all the formats in WORK when you ran

proc format library = work.formats cntlout = cntlout;
run;

Now you can look in that dataset (WORK.CNTLOUT) and replace the value you want to have replaced.

After that, use the dataset as input for proc format:

proc format library = work.formats cntlin = cntlout;
run;

Re: Update Existing Format Value

Sanket — Mon, 20 Mar 2017 05:06:40 GMT

Thank you !! KurtBresmer 🙂 It worked fine on Friday I tried with an below example. proc format; value $id '1'='Mary' '2'='Tom' '3'='Joe' ; run; options fmtsearch=(work); proc format fmtlib library=work.formats; select $id; run; quit; proc format library = work.formats cntlout = cntlout; select $id; run; proc sql; update cntlout set LABEL='Kim' where label='Joe'; quit; Now you can look in that dataset (WORK.CNTLOUT) and replace the value you want to have replaced. After that, use the dataset as input for proc format:; proc format library = work.formats cntlin = cntlout; select $id; run; proc format library = work.formats cntlout = cntlout; select $id; run;

Re: Update Existing Format Value

Kurt_Bremser — Mon, 20 Mar 2017 07:52:06 GMT

Use the "little running man" icon in the top of your "Post" or "Reply" window to post SAS code. This preserves the formatting and even gives you enhanced-editor-like coloring:

proc format;
value $id
  '1'='Mary'
  '2'='Tom'
  '3'='Joe'
;
run;

options fmtsearch=(work);

proc format fmtlib library=work.formats;
select $id;
run;

quit; * not necessary;

proc format library = work.formats cntlout = cntlout;
select $id;
run;

proc sql;
update cntlout
set LABEL='Kim'
where label='Joe';
quit;

proc format library = work.formats cntlin = cntlout;
select $id;
run;

proc format library = work.formats cntlout = cntlout;
select $id;
run;