topic regex in SAS Programming

SAS regex

SASPhile — Fri, 03 Mar 2017 20:43:59 GMT

did the subject complete the entire course of study
did the subject complete the treatment period
did subject complete full study protocol
did subject complete hospital visit
did subject complete application form

There is a text field with above text. I would like to select only those records which contain the key words "subject" "complete" along with "study" or "treatment" or "protocol".
any help on regex?

regex

SASPhile — Fri, 03 Mar 2017 20:58:57 GMT

There is a text field with above text. I would like to select only those records which contain the key words "subject" "complete" along with "study" or "treatment" or "protocol".
the output records are:
did the subject complete the entire course of study
did the subject complete the treatment period
did subject complete full study protocol

any help on regex?

Re: SAS regex

Reeza — Fri, 03 Mar 2017 21:01:16 GMT

PLEASE edit your posts, don't post duplicates.

Re: regex

FriedEgg — Fri, 03 Mar 2017 22:53:19 GMT

data f;
length str $ 64;
array x[2] $  8 _temporary_ ('subject' 'complete');
array y[3] $  9 _temporary_ ('study' 'treatment' 'protocol');
input str &;
j=0;
do i=1 to dim(x);
  j+findw(str,x[i],,'tsmi')>0;
end;
if j=dim(x) and prxmatch('/\b('||catx('|',of y[*])||')\b/i',str)>0;
cards;
did the subject complete the entire course of study
did the subject complete the treatment period
did subject complete full study protocol
did subject complete hospital visit
did subject complete application form
;
run;

Re: regex

SASPhile — Fri, 03 Mar 2017 21:39:15 GMT

Hi,

The final output should contain only these three records as I'm looking for combination of subject complete along with either study,treatment or protocol

did the subject complete the entire course of study
did the subject complete the treatment period
did subject complete full study protocol

Re: SAS regex

art297 — Fri, 03 Mar 2017 22:19:47 GMT

Matt's (@FriedEgg) code did that, but showed the results in the log rather than the file. A minor change to his code puts the results in a file:

data want;
  length str $ 64;
  array x[2] $  8 _temporary_ ('subject' 'complete');
  array y[3] $  9 _temporary_ ('study' 'treatment' 'protocol');
  input str &;
  j=0;
  do i=1 to dim(x);
    j+findw(str,x[i],,'tsmi')>0;
  end;
  if j=dim(x) and prxmatch('/('||catx('|',of y[*])||')/i',str)>0;
  cards;
did the subject complete the entire course of study
did the subject complete the treatment period
did subject complete full study protocol
did subject complete hospital visit
did subject complete application form
;
run;

Art, CEO, AnalystFinder.com

Re: SAS regex

FriedEgg — Fri, 03 Mar 2017 22:39:23 GMT

Updated my post

Re: SAS regex

ChrisBrooks — Fri, 03 Mar 2017 22:45:17 GMT

Try this

data in;
length str $64;
input str &;
cards;
did the subject complete the entire course of study
did the subject complete the treatment period
did subject complete full study protocol
did subject complete hospital visit
did subject complete application form
;
run;

data out;
	set in;
	if prxmatch("/\bsubject\b.*\bcomplete\b.*(\bstudy\b|\btreatment\b|\bprotocol\b)/",str)
 then output;
run;

The \b characters force the regex to match only on word boundaries and \b.* means their can be multiple words between the matching ones.

Re: SAS regex

FriedEgg — Fri, 03 Mar 2017 22:52:55 GMT

it can be a bit simplified:

/\bsubject\b.*\bcomplete\b.*\b(study|treatment|protocol)\b/i

the reason I chose not to do this was to avoid the assumed logic that the words would always be in this order.

Re: SAS regex

ChrisBrooks — Sat, 04 Mar 2017 00:23:19 GMT

That's a good point about word order - you could probably do something with capture groups if they could appear in any order.

Re: SAS regex

SASPhile — Mon, 06 Mar 2017 18:51:56 GMT

Thanks! and any words we dont want, can be separated out like [^do not include] , right?

Re: SAS regex

FriedEgg — Mon, 06 Mar 2017 19:01:14 GMT

[^] creates a negated set, it is specific to the characters within the set, no strings.

Re: SAS regex

SASPhile — Mon, 06 Mar 2017 19:53:13 GMT

to exlcude the list then itset prxmatch(list1|list2!..columnname)=0 must work