topic Us %sysfunc or %substr to create fiscal year in SAS Programming

Us %sysfunc or %substr to create fiscal year

Solph — Thu, 02 Mar 2017 22:56:41 GMT

I'm doing something on my data files that contain fiscal year values (e.g. 1314, 1415) in the file name, and my %do %to year valus are 4-digit values (e.g. 2014, 2015). How do I create fiscal year values using such as sysfuncs? Here is the sample code. The one I wrote didn't work.

data have2014; input id;
datalines;
1
2
3
;
run;

data have2015; set have2014; run;

%macro renm;
%do year=2014 %to 2015;
%let fy= %substr(&year,3,2)%sysfunc(putn(%eval(substr(&year,3,2).+1),z2.))
data want&year; set have&fy;
%end;
%mend;
%renm;

So the input file names are have1415, have1516, and

I'd like to produce output file names want2014 and 2015.

Thanks.

Re: Us %sysfunc or %substr to create fiscal year

Astounding — Thu, 02 Mar 2017 23:56:13 GMT

Relying on the last statement in your post, here is an example of how to change from have1415 to want2014 (and also from have1516 to want2015).

%macro renm;

%local year fy;
%do year=2014 %to 2015;
%let fy= %substr(&year,3,2);

%let fy = &fy%sysfunc(putn(%eval(&fy+1),z2));
data want&year; set have&fy;
%end;
%mend;
%renm

I can't test it right now, and it looks only mildly different than your original. In fact, if you had changed SUBSTR to %SUBSTR in your longer statement, it might have worked. (Removing the dot after z2 probably works either way.)

Re: Us %sysfunc or %substr to create fiscal year

Reeza — Thu, 02 Mar 2017 23:58:25 GMT

%let fy= %substr(&year,3,2)%eval(%substr(&year,3,2)+1);

Re: Us %sysfunc or %substr to create fiscal year

Astounding — Fri, 03 Mar 2017 00:00:46 GMT

Reeza,

I suspect that would work for the years in the example, but would lose the leading zero when one exists in the second half of the fiscal year.

Re: Us %sysfunc or %substr to create fiscal year

Reeza — Fri, 03 Mar 2017 00:08:59 GMT

@Astounding You are correct 🙂

This is why I always create my macro variables in a data step rather than macro code.

%let fy= %substr(&year,3,2)%sysfunc(putn(%eval(%substr(&year,3,2)+1), z2.));

Re: Us %sysfunc or %substr to create fiscal year

Solph — Fri, 03 Mar 2017 17:40:46 GMT

Thanks a lot. It worked and for pointing the obvious errors I missed and the concatenated line by Reeza:

%let fy= %substr(&year,3,2)%sysfunc(putn(%eval(%substr(&year,3,2)+1), z2.));

data have1415; input id;
datalines;
1
2
3
;
run;
data have1516; set have1415; run;

%macro renm;
%do year=2014 %to 2015;
%let fy= %substr(&year,3,2)%sysfunc(putn(%eval(%substr(&year,3,2)+1), z2.));
data want&year; set have&fy; run;
%end;
%mend;
%renm;