topic Re: Keep if start with letter in SAS Programming

Keep if start with letter

user24 — Thu, 02 Mar 2017 14:29:39 GMT

How can i remove the data if the variable is not start with a letter. Should i type all the letter or any other short way

variable

A153

B124

0564

.1548

w853

I want to keep only these variables. It should be 4 character long

variable

A153

B124

w853

Re: Keep if start with letter

PeterClemmensen — Thu, 02 Mar 2017 14:31:42 GMT

What about 'na'? That starts with a letter two?

Anyway, something like this

data have;
input variable $;
datalines;
 A153
B124
0564
.1548
na
w853
;

data want;
   set have;
   where substr(variable,1,1) not in ('0','1','2','3','4','5','6','7','8','9','.',' ');
run;

Re: Keep if start with letter

user24 — Thu, 02 Mar 2017 14:35:56 GMT

how can i remove if the character long not more than 4 or less than 4

Re: Keep if start with letter

Kurt_Bremser — Thu, 02 Mar 2017 14:38:41 GMT

Use the length() function to determine the current string length.

Re: Keep if start with letter

RW9 — Thu, 02 Mar 2017 14:39:32 GMT

Pretty sure your just pulling our leg now, we ask for test data in the form of a datastep every post. As such this is just logic snippets:

data want;
  string="A153";
  isfirstalpha=ifn(lengthn(compress(char(string,1)," ","a")),0,1);
  islength=lengthn(string);
run;

Re: Keep if start with letter

Astounding — Thu, 02 Mar 2017 14:47:30 GMT

A short way:

if length(variable)=4 and anyalpha(variable)=1;

By using ANYALPHA, you don't have to guess what characters might arrive in the next batch of data.

Re: Keep if start with letter

RW9 — Thu, 02 Mar 2017 14:50:37 GMT

Just to note its only the first character, so:

if length(variable)=4 and anyalpha(char(variable,1))=1;

Good point about anyalpha() function, saves compress.

Re: Keep if start with letter

Astounding — Thu, 02 Mar 2017 15:05:17 GMT

No, the complications aren't needed. I stand by my original post.

ANYALPHA returns the position of the first alpha character. So by checking that ANYALPHA returns a 1, that's enough.

Re: Keep if start with letter

Ksharp — Fri, 03 Mar 2017 10:33:34 GMT

data have;
input variable $;
datalines;
 A153
B124
0564
.1548
na
w853
;
data want;
 set have;
 if prxmatch('/^[a-z]\S{3}$/i',strip(variable));
run;

Re: Keep if start with letter

art297 — Fri, 03 Mar 2017 04:54:59 GMT

I think@Ksharp meant the following (to ensure that strings were only 4 characters long):

data have;
input variable $;
datalines;
 A153
B124xxx
d5555
0564
.1548
na
AAAA
w853
;
data want;
 set have;
 if prxmatch('/^[a-z][a-z0-9]{3}$/i',strip(variable));
run;

Art, CEO, AnalystFinder.com

Re: Keep if start with letter

Ksharp — Fri, 03 Mar 2017 10:15:42 GMT

Yeah.I forgot $ .