topic Re: listing macro variable's values with prefix in a procedure in SAS Programming

listing macro variable's values with prefix in a procedure

ShinCrayons — Wed, 22 Feb 2017 07:29:31 GMT

I have a macro variable:

%let par = var1 var2 var3;

Now I want to use those values in a procedure like this

proc score data=test type=parms score=par out=score; var W_var1 W_var2 W_var3; run;

For example, if var1=age then I want to list W_age in the var statement. I tried var W_&par; but it doesn't work. Can anyone help me with a simple solution here? Thanks a bunch!!

Re: listing macro variable's values with prefix in a procedure

jklaverstijn — Wed, 22 Feb 2017 07:41:05 GMT

Hi,

The code W_&par would merely give you "W_var1 var var". You must parse out the macro variable par and prefix the W_ for each word in the value. Based upon a sample code in the SAS usage notes, this woujld be a good start:

options mprint;
%macro test(string);
  %let word_cnt=%sysfunc(countw(%superq(string)));   /* Count # words */
proc score data=test type=parms score=par out=score;
var
  %do i = 1 %to &word_cnt;
    %let var&i=%qscan(%superq(string),&i,%str( ));   /* get i'th word  */
    W_&&var&i   /* add prefix */
  %end;
; run;
%mend test;

%let par = var1 var2 var3;
%test (&par);

Hope this helps,

Jan.

Re: listing macro variable's values with prefix in a procedure

Ksharp — Wed, 22 Feb 2017 08:22:14 GMT

%let par = var1 var2 var3;
%let score=%sysfunc(prxchange(s/(\w+)/W_$1/,-1,&par));

%put &score ;

Re: listing macro variable's values with prefix in a procedure

jklaverstijn — Wed, 22 Feb 2017 08:28:31 GMT

Nice and consice. I like it!

Re: listing macro variable's values with prefix in a procedure

ShinCrayons — Wed, 22 Feb 2017 10:15:45 GMT

what if I want to add '1' at the end of every values of &par? I'm confusing about how prxchange function work.

Re: listing macro variable's values with prefix in a procedure

Ksharp — Wed, 22 Feb 2017 11:42:03 GMT


%let par = var1 var2 var3;
%let score=%sysfunc(prxchange(s/(\w+)/W_\11/,-1,&par));

%put &score ;