topic Re: Remove a string from a macro variable in SAS Programming

Remove a string from a macro variable

apolitical — Mon, 13 Feb 2017 16:28:38 GMT

if I define 2 lists of variables as :

%let varlist1 = v1 v2 v3

%let varlist2 = v3

How could I generate a new variable list consisting of v1 and v2 by subtracting varlist2 from varlist1? The following command does not seem to give what I want.

%let varlist3 = tranwrd(&varlist1., &varlist2., '').

Thanks.

Re: Remove a string from a macro variable

ErikLund_Jensen — Mon, 13 Feb 2017 16:35:12 GMT

Yout code works, but you must call tranwrd inside a %sysfunc macro function to use it outside a data step, and also omit the quotes around the empty value, as they are considered part of the value in macro language.

%let varlist3 = %sysfunc(tranwrd(&varlist1., &varlist2., %str()));

Re: Remove a string from a macro variable

apolitical — Mon, 13 Feb 2017 16:38:49 GMT

It works. Thank you!

Re: Remove a string from a macro variable

ErikLund_Jensen — Mon, 13 Feb 2017 16:39:25 GMT

- Note that it only works with 1 value in varlist2, as the tranword function takes the list as a single string to search for. It is more complicated with several values. Do you need that?

Re: Remove a string from a macro variable

Tom — Mon, 13 Feb 2017 16:46:03 GMT

You probably need to consider the possibility that the name of the variable you want to remove is a substring of another variable in your list. You could add some spaces to the first two arguments to make it match words. Also watch out for case of the variable names.

10   %let varlist=V1v3 V2 V3 ;
11   %let var=v3 ;
12   %let want=%sysfunc(tranwrd(%str( %upcase(&varlist) ),%str( %upcase(&var) ),%str( )));
13   %put WANT=|&want|;
WANT=|V1V3 V2|

Now if you want to the second parameter to also be a list you will need a more complicated solution. You could do it with %DO looip or possible using regular expressions.

Re: Remove a string from a macro variable

apolitical — Mon, 13 Feb 2017 16:49:12 GMT

Yes I would like to know that. What if varlist2 is defined as
%varlist2 = v1 v2;

Re: Remove a string from a macro variable

apolitical — Mon, 13 Feb 2017 16:58:03 GMT

As you all suggested, this solution doesn't work if varlist 2 contains multiple stirngs separated by spaces. In fact, none of the components would be removed from varlist1. Can you please give a solution to that scenario?

Re: Remove a string from a macro variable

ErikLund_Jensen — Mon, 13 Feb 2017 17:09:21 GMT

It comes here.. You need a macro to remove the values in varlist2 one at a time.

%let varlist1 = V1 V2 V3 V4 V5;
%let varlist2 = V3 V1 ;

%macro m;
%global varlist3;
%let varlist3 = &varlist1;
%do i = 1 %to %sysfunc(countw(&varlist2));
%let varlist3 = %sysfunc(tranwrd(&varlist3., %scan(&varlist2.,&i,%str( )), %str()));
%end;
%let varlist3 = %sysfunc(compbl(&varlist3));
%mend;
%m;
%put &varlist3;

Re: Remove a string from a macro variable

Tom — Mon, 13 Feb 2017 17:21:53 GMT

If you need to do it totally in macro code then you probably want a loop. For example you could make a new macro "function".

%macro subset(list1,list2);
%local i word result;
%do i=1 %to %sysfunc(countw(&list1));
   %let word=%scan(&list1,&i);
   %if not %index(%str( %upcase(&list2) ),%str( %upcase(&word) )) %then
     %let result=&result &word 
  ;
%end;
&result.
%mend subset;

So then you can use it this way.

38   %let want=%subset(V1 v2 v3 v4 v5 V3v2,V3 v2);
39   %put WANT=|&want|;
WANT=|V1 v4 v5 V3v2|

Re: Remove a string from a macro variable

apolitical — Mon, 13 Feb 2017 20:10:48 GMT

Thanks so much. I got it to work.

Re: Remove a string from a macro variable

Ksharp — Tue, 14 Feb 2017 03:28:52 GMT

%let varlist1 = V1 V2 V3 V4 V5;
%let varlist2 = V3 V1;

%let pid=\b%sysfunc(prxchange(s/\s+/\b|\b/,-1,&varlist2))\b;
%let want=%sysfunc(prxchange(s/&pid//i,-1,&varlist1));

%put &want;