topic Re: creating survival data in SAS Programming

creating survival data

Jest — Sun, 12 Feb 2017 14:50:25 GMT

I have a longitudinal dataset with time variables (months) and event (0,1)...

How can I create a data table showing the time as when the event occurred and if the event did not occur the last follow-up time.

This is how the data looks.

ID Time Event

1 0 0

1 1 0

1 2 1

1 3 1

1 4 1

2 0 0

2 1 0

2 2 0

2 3 0

2 4 0

I want the data to look like:

ID time event

1 2 1

2 4 0

Thanks

Re: creating survival data

art297 — Sun, 12 Feb 2017 14:57:33 GMT

Here is one way:

data want (drop=_:);
  set have;
  retain _need;
  by id;
  if first.id then _need=1;
  if _need and (event eq 1 or last.id) then do;
    output;
    _need=0;
  end;
run;

HTH,

Art, CEO, AnalystFinder.com

Re: creating survival data

mkeintz — Sun, 12 Feb 2017 16:38:08 GMT

Another way:

data want;

set have;

by id event;

if (first.event=1 and event=1) or (last.id=1 and event=0);

run;

This assumes that once a record with event=1 occurs, then event stays at 1 for the remaining records of the id. And it assumes that data are sorted by ID.