topic Re: Cannot transform imported char variable in SAS Programming

Cannot transform imported char variable

KonstantinV — Sat, 11 Feb 2017 13:36:49 GMT

I am importing a csv file. After dropping the first lines with the metadata I am trying to transform the two columns into date and numeric formats respectively:

proc import datafile="/path/RealGDP2001-20016_Bulgaria.csv"
out=GDP_Bulgaria dbms=csv replace; 
getnames=no; 
run;

data GDP_Bulgaria; set GDP_Bulgaria; 
	if _n_>5; 
run;
                                                             

data GDP_Bulgaria; set GDP_Bulgaria; 
	date = input(var1, YYQ6.);
	format date yyq.;
	GDP = input(var2,8.);
	drop var1;
run;

No problems with the date, however for the numeric variable nothing seems to work. I tried compress(), trim(), strip() and vvalue() transformations before attempting to convert without success.

The problem seems to be related with the fact that some values have minus and other dont. If I change the variable length to 4 then those with minus are converted but the others aren't regardless if I am using compress or not.

Re: Cannot transform imported char variable

Shmuel — Sat, 11 Feb 2017 14:04:54 GMT

Change GDP informat:

GDP = input(var2,best8.1);

Re: Cannot transform imported char variable

KonstantinV — Sat, 11 Feb 2017 14:37:39 GMT

I just tried but it doesn't work.

Re: Cannot transform imported char variable

Astounding — Sat, 11 Feb 2017 15:03:47 GMT

Your results are consistent with VAR2 being numeric originally. All you would need to do is rename it to GDP.

Re: Cannot transform imported char variable

art297 — Sat, 11 Feb 2017 15:43:53 GMT

Not sure what your problem is since your code does work for me. However, that said, here is a work around the should work:

proc import datafile="c:\art\RealGDP2001-20016_Bulgaria.csv"
out=GDP_Bulgaria dbms=csv replace; 
getnames=no;
datarow=6;
run;

data GDP_Bulgaria;
  set GDP_Bulgaria (rename=(var2=GDP));
  date = input(var1, YYQ6.);
  format date yyq.;
  drop var1;
run;

HTH,

Art, CEO, AnalystFinder.com

Re: Cannot transform imported char variable

Tom — Sat, 11 Feb 2017 23:42:11 GMT

Don't use PROC IMPORT to read a CSV file with only two columns. It will take less code to write the DATA step, plus you get to have complete control over the variable names and types.

data want ;
  infile cards dsd firstobs=6 truncover;
  length Date GDP 8 ;
  informat date yyq. ;
  format date yyq6. ;
  input Date GDP ;
cards4;
Data Source in SDW: http://sdw.ecb.europa.eu/quickview.do?SERIES_KEY=320.MNA.Q.Y.BG.W2.S1.S1.B.B1GQ._Z._Z._Z.XDC.LR.GY
,MNA.Q.Y.BG.W2.S1.S1.B.B1GQ._Z._Z._Z.XDC.LR.GY
",""Gross domestic product at market prices - Bulgaria - Domestic (home or reference area), Total economy, Domestic currency (incl. conversion to current currency made using a fix parity), Chain linked volume (rebased), Growth rate, over 1 year, Calendar a
Collection:,Summed through period (S)
Period\Unit:,
2016Q3,3.4
2016Q2,3.6
2016Q1,3.4
2015Q4,3.7
;;;;