topic Re: Proc Tabulate : creating a row of zeros for nonexistent variable in SAS Programming

Proc Tabulate : creating a row of zeros for nonexistent variable

Bootler — Thu, 09 Feb 2017 19:03:28 GMT

Hello, this is my code and it produces the graph below.

Proc tabulate data=sample;
class term type;
table (Type=" ") (all="Total Undergraduate - Campus"),(term="Headcount")/misstext = "0";
keylabel n=" ";
format type $type. term $terms.;
run;

	Headcount
Fall 2015	Spring 2016	Summer 2016	2015
Adult Degree	120	130	114	118
RN	45	32	34	41
Traditional Undergraduate	200	181	192	212
Total Undergraduate - Campus	365	343	340	371

My data is listed as:

Data Fall2015;
input Term $ Cr_Att Type $;
datalines;
15FALL 3 RN
15FALL 12 TU

;

run;

I was wondering if there is a way to create a row category of all zeros for a variable (Type ="GS") that does not in my dataset.

Below is an example

	Headcount
Fall 2015	Spring 2016	Summer 2016	2015
Adult Degree	120	130	114	118
Grad students	0	0	0	0
RN	45	32	34	41
Traditional Undergraduate	200	181	192	212
Total Undergraduate - Campus	365	343	340	371

Re: Proc Tabulate : creating a row of zeros for nonexistent variable

ballardw — Thu, 09 Feb 2017 19:12:14 GMT

Create a format to associate with the class variable with all of the values which it looks like you may have, use the PRELOADFMT option on class statement.

This may do it:

Proc tabulate data=sample;
   class term ;
   class type/preloadfmt order=data  ;
   table (Type=" ") (all="Total Undergraduate - Campus"),(term="Headcount")/ printmiss misstext = "0";
   keylabel n=" ";
   format type $type. term $terms.;
run;

Re: Proc Tabulate : creating a row of zeros for nonexistent variable

FriedEgg — Thu, 09 Feb 2017 19:14:24 GMT

proc format;
value $gndr
'F' = 'Female'
'M' = 'Male'
'O' = 'Other';
run;

proc tabulate data=sashelp.class;
class sex / preloadfmt;
table sex/ printmiss misstext='0';
format sex $gndr.;
run;

Re: Proc Tabulate : creating a row of zeros for nonexistent variable

Bootler — Tue, 14 Feb 2017 18:48:53 GMT

Thanks I already had a format in place, so all i did was add the preloadfmt and printmiss options.

Proc tabulate data=sample;
class term type/preloadfmt;
table (Type=" ") (all="Total Undergraduate - Campus"),(term="Headcount")/ printmiss misstext = "0";
keylabel n=" ";
format type $type. term $terms.;
run;