topic Re: input methods in SAS Programming

input methods

Garik — Tue, 31 Jan 2017 20:01:17 GMT

Hi, there.

I have such question.

If I have sas code as is below and the result should be as shown at the end, what to write instead of the question marks.

data input_method;

input GG$ HH$ ????????????????;

datalines;
G A R I K
H A K O B Y A N
;
run;

////////////////////////////////////////////////////

GG HH

G H

A A

R K

I O

K B

Re: input methods

Kurt_Bremser — Tue, 31 Jan 2017 20:26:07 GMT

The datalines need to be written in the same way as the intended result. That's quite obvious, isn't it?

Re: input methods

Garik — Tue, 31 Jan 2017 20:36:23 GMT

if dataline contanins huge amount of lines.

is there any way to do so or not?

Re: input methods

Astounding — Tue, 31 Jan 2017 20:44:31 GMT

Here's one approach. You may benefit by adding LENGTH statements for GG and HH:

data input_method;

infile datalines truncover;

input GG_list & $60. / HH_list & $60.;

do _n_=1 by 1 until (GG=' ' and HH=' ');

GG = scan(GG_LIST, _n_);

HH = scan(HH_LIST, _n_);

if GG > ' ' or HH > ' ' then output;

end;

keep gg hh;

datalines;

G A R I K

H A K O B Y A N

;

Re: input methods

Tom — Tue, 31 Jan 2017 20:45:28 GMT

Looks like a simple transpose problem. Not sure where you came up the name for columns in the resulting output. This will just name them row1, row2, etc .

data raw ;
  length row col 8 value $20 ;
  infile cards col=cc length=len truncover ;
  row+1;
  do col=1 by 1 until ( cc > len) ;
    input value @ ;
    output;
  end;
cards;
G A R I K
H A K O B Y A N
Another set of values
;

proc sort data=raw;
  by col row ;
run;

proc transpose data=raw prefix=row out=want(drop=_name_);
  by col ;
  id row ;
  var value ;
run;

Re: input methods

ballardw — Tue, 31 Jan 2017 20:48:12 GMT

This will do what you are requesting but is not going to be easily extended to a generic use. The 14 would have to be replaced by the length of the longest line and the better be a space between each character. If the spaces came from a double-byte character set then maybe you wouldn't need the "by 2" bit depending on your current session encoding.

data input_method;
   infile datalines n=2 truncover;
   do i=1 to 14 by 2;
      input #1 @i GG $  #2 @i  HH $ @@ ;
      output;
   end;
   drop i;
input;
datalines;
G A R I K      
H A K O B Y A N
;
run;

If you have an actual application for this then you might look at reading the entire line(s) into variables and parsing.