topic Re: Informat for date in the form MM.YYYY in SAS Programming

Informat for date in the form MM.YYYY

ShagilImam — Sun, 22 Jan 2017 11:02:23 GMT

Hi,

What informat shall I use to input a date in the form MM.YYYY (period as separator). Example: March 2016 is represented as 03.2016.

ANYDTDTE7. works when hyphen (-) or slash (/) are used as separators. Returns a missing value when period is used as a separtor.

Thanks.

Re: Informat for date in the form MM.YYYY

Astounding — Sun, 22 Jan 2017 13:19:31 GMT

Dates in SAS refer to a particular day. If you have just the month and year (in any format), you first need to decide what day of the month to use in order to convert your data to a SAS date.

Re: Informat for date in the form MM.YYYY

ShagilImam — Sun, 22 Jan 2017 13:38:17 GMT

Hi,

Thanks for your reply.

'Day' does not really matter; it can be taken as 01.

I just need to read a file which will have month and year for a particular event.

As I mentioned, ANYDTDTE7. works fine with hyphen or slash as separators, that is, the following code gives expected output as 10.2016

data _null_;
informat dte anydtdte7.;
format dte mmyyp7.;
input dte;
put dte;
datalines;

10/2016
;
run;

Taking 10-2016 in place of 10/2016 also works; but unfortunately, my input will be as 10.2016, which gives a missing value as output.

Re: Informat for date in the form MM.YYYY

Astounding — Sun, 22 Jan 2017 13:45:41 GMT

In that case, you might have to work around the problem by reading as text then changing "." to "/":

input textvar $;

dte = input( translate(textvar, '/', '.'), anydtdte7.);

Re: Informat for date in the form MM.YYYY

Shmuel — Sun, 22 Jan 2017 17:03:39 GMT

Just for the fun you may even do (code tested and is ok):

data test;

input date best7.4;

date = input('01'||put(date*10000,z6.),ddmmyy8.);

format date ddmmyy10.;

datalines;

03.2017

11.2016

5.1999

; run;

Re: Informat for date in the form MM.YYYY

ChrisNZ — Sun, 22 Jan 2017 22:16:09 GMT

You can read an external file directly if you redefine the value to read on the fly, and add the missing day :

proc format;
  invalue mmyyp (default=10)
          's/(.{7})/01.\1/o' (regexpe)=[ddmmyy10.];
run;

data WANT;
  input DATE mmyyp.;
  putlog DATE= date9. ;
cards;
03.2016
run;

DATE=01MAR2016

More examples about all valid SAS regular expressions, including their use in informats, by following this link: