topic Re: read data AAAA-MM-DD-HH.MM.SS.nnnnnn in SAS Programming

read data AAAA-MM-DD-HH.MM.SS.nnnnnn

Rakeon — Mon, 09 Jan 2017 11:49:44 GMT

Hi I have to import in datatime SAS this datetime:

2011-02-28-23.59.59.999999

2015-05-22-11.21.17.558222

2015-05-22-12.13.30.386022

I try with this code:

data prova;
	a='2011-02-28-23.59.59.999999';
	b= input(a,ANYDTDTM26.);
	c=put(b,datetime.);
run;

But I get the missing value...
I can't find the correct informat for this type of data....
Any of you, has some suggestion?

Re: read data AAAA-MM-DD-HH.MM.SS.nnnnnn

error_prone — Mon, 09 Jan 2017 12:18:44 GMT

Using anydtdtm. instead of anydtdtm26. seems to solve the issue.

Re: read data AAAA-MM-DD-HH.MM.SS.nnnnnn

Daniel-Santos — Mon, 09 Jan 2017 14:06:48 GMT

I think anyddtm. will truncate the milliseconds part.

Try this to precisely input the datetime.

data _null_;

a='2011-02-28-23.59.59.999999';

b=inputn(substr(a,1,10),'yymmdd10.')*24*60*60+inputn(substr(a,12),'time15.');

put b datetime25.6;

run;

This will split the datetime into two parts and input them separately with the correct informat.

Hope it helps.

Daniel Santos @ www.cgd.pt

Re: read data AAAA-MM-DD-HH.MM.SS.nnnnnn

Kurt_Bremser — Mon, 09 Jan 2017 14:44:47 GMT

Convert the input data to a properly formatted ISO 8601 datetime value, and then use the proper informat:

data have;
input value_char $26.;
substr(value_char,11,1) = 'T';
substr(value_char,14,1) = ':';
substr(value_char,17,1) = ':';
value = input(value_char,e8601dt26.6);
format value datetime26.6;
cards;
2011-02-28-23.59.59.999999
2015-05-22-11.21.17.558222
2015-05-22-12.13.30.386022
;
run;

Instead of the 'T', you can also use a blank. But the 'T' conforms to the norm.

Re: read data AAAA-MM-DD-HH.MM.SS.nnnnnn

data_null__ — Mon, 09 Jan 2017 14:55:54 GMT

SAS has an informat for that. YMDDTTM.

data date;
   input date:ymddttm.;
   line=_infile_;
   format date datetime32.6;
   cards;
2011-02-28-23.59.59.999999
2015-05-22-11.21.17.558222
2015-05-22-12.13.30.386022
;;;;;
   run;
proc print;
   run;