topic Re: How to convert Char to Numeric in SAS Programming

How to convert Char to Numeric

pritam26 — Fri, 06 Jan 2017 08:22:44 GMT

Given Dataset: All hav Char type, i need to change the date type to numeric with odinal value.

Gender	Married	Dependents	Education
Male	Yes	0	Graduate
Male	Yes	1	Graduate
Male	Yes	2	Graduate
Male	Yes	2	Graduate
Male	No	0	Not Graduate
Male	Yes	0	Not Graduate

Used Proc format to change the format:
proc format;
value $G
'Male'=1 'Female'=0;
Value $M
'Yes'=1 'No'=0;
value $D
"0"=0 "1"=1 "2"=2 "3+"=3;
value $E
"Graduate"=1 "Not Graduate"=0 ;

run;

BUT NOW HOW I CAN CHANGE THE TYPE FROM CHAR TO NUMERIC??

Re: How to convert Char to Numeric

Daniel-Santos — Fri, 06 Jan 2017 08:43:02 GMT

Hi.

It actually works if you explicitly define the needed vars as numeric.

You can use the LENGTH statement for this.

data _OUT1;
length GENDERN 8.;
GENDERN=put('Male',$G.);
run;

Off course this will produce a warning, as SAS is implictly doing the type conversion for you.

Another way of doing this, and surely the right way would be to create numeric informats instead of formats.

For example:

proc format;
invalue G
'Male'=1 'Female'=0;
invalue M
'Yes'=1 'No'=0;
invalue D
"0"=0 "1"=1 "2"=2 "3+"=3;
invalue E
"Graduate"=1 "Not Graduate"=0 ;

run;

data _OUT2;
GENDERN=input('Male',G.);
run;

Hope it helps.

Daniel Santos @ www.cgd.pt

Re: How to convert Char to Numeric

Patrick — Fri, 06 Jan 2017 09:02:17 GMT

Not sure why you have to recode your variables this way but to answer your question: Use a numeric INformat as this will allow you to read a string and translate it into a numeric value.

proc format;
  invalue sex_num
    "Male" =1
    "Female"=2
    other=99
   ;
quit;

data sample;
  sex="Female";
  sex2=input(sex,sex_num.);
run;

Re: How to convert Char to Numeric

pritam26 — Fri, 06 Jan 2017 09:06:48 GMT

Need to run regression model. Thanks for the help

Re: How to convert Char to Numeric

Patrick — Fri, 06 Jan 2017 09:19:30 GMT

If your source data is not already standardized then also use the UPCASE option so that the informat is no more case sensitive.

proc format;
  invalue sex_num (just upcase)
    "MALE"  =1
    "FEMALE"=2
    other=99
    ;
quit;

data sample;
  sex="female";
  sex2=input(sex,sex_num.);
run;

UPCASE

converts all raw data values to uppercase before they are compared to the possible ranges. If you use UPCASE, then make sure the values or ranges that you specify are in uppercase.

http://support.sas.com/documentation/cdl/en/proc/69850/HTML/default/viewer.htm#p1pmw90bl3jzgdn1w4202kclxtho.htm