topic Re: create variables from observations in SAS Programming

create variables from observations

rmlmrmlm — Thu, 29 Dec 2016 19:06:08 GMT

Hello.

I have a dataset with only one variable and 50 observations. The variable contains names of other I want to use to create a new dataset. Of course, these names change, depending on the steps of the processing.

Example of the dataset_1:

variable_name
--------------------
brand
colour
year
maxspeed

The new dataset to create, dynamicaly and empty, must have the following variables:

Example of dataset_2:

brand colour year maxspeed
------------------------------------------------

This is some kind of transpose. I tried some transposes but it didn't work out.

Can someone help?
Thanks a lot.

Re: create variables from observations

Kurt_Bremser — Thu, 29 Dec 2016 19:09:32 GMT

You need more information in your first dataset, not just names: variable type, length, formats, ...

Re: create variables from observations

rmlmrmlm — Thu, 29 Dec 2016 19:10:57 GMT

Important: It's not possible to use the select variable into :var separated by ' ' because sometime we have so many columns that concatenated it exceeds the max lengrh of a macro variable.

Re: create variables from observations

rmlmrmlm — Thu, 29 Dec 2016 19:14:24 GMT

Yes, you are right! I didn' think about it. SAS rookie.

Re: create variables from observations

rmlmrmlm — Thu, 29 Dec 2016 19:19:48 GMT

Well ... I was checking ... In real life, the variables are all numeric.

Can I use a kind of transpose, @Kurt_Bremser?

Re: create variables from observations

Reeza — Thu, 29 Dec 2016 20:03:11 GMT

You only have one column? What would be in the variables created, missing? A full example would be helpful.

Re: create variables from observations

Astounding — Thu, 29 Dec 2016 20:11:09 GMT

Here's a transpose approach:

data have2;

set have;

num_var = 1;

run;

proc transpose data=have2 out=want1 (drop=_name_ _label_);

var num_var;

id variable_name;

run;

data want2;

set want1;

stop;

run;

The transpose creates all the numeric variables with a value of 1. The final DATA step removes that observation, but leaves the variable definitions in place.

Re: create variables from observations

Shmuel — Thu, 29 Dec 2016 20:23:12 GMT

You can do it in one step, assumed all variables are numeric:

data _NULL_;

infile datalines truncover;

input vname $;

if _N_ = 1 then call exceute('data test; length ');

if vname ne '===' /* input data assigned to end of input */

then call execeute('strip(vname) || ' ');

else call excecute(' 8; delete; run;');

datalines;

brand

colour

year

maxspeed

===

; run;

run;

Re: create variables from observations

PGStats — Thu, 29 Dec 2016 20:30:22 GMT

You can also use a temporary file:

filename toto temp;

data _null_;
set have;
file toto;
put variable_name "=0;";
run;

data have;
%include toto;
stop;
run;

Re: create variables from observations

Ksharp — Fri, 30 Dec 2016 03:53:23 GMT

data have;
input name : $20.;
cards;
brand
colour
year
maxspeed
;
run;
proc transpose data=have out=want;
id name;
run;

Re: create variables from observations

rmlmrmlm — Fri, 30 Dec 2016 15:14:06 GMT

For my needs, this answer is valid.
Thanks.

Re: create variables from observations

gk6565 — Thu, 05 Jan 2017 08:58:08 GMT

Thanks for this useful answer.

It's working.! Kudos to you.