topic Re: creating conditions using date range and generating a macro variable in SAS Programming

creating conditions using date range and generating a macro variable

yo1 — Wed, 28 Dec 2016 22:16:25 GMT

Hello everyone,

I am trying to create a macro variable conditional on a date range. The condition is if todays date (according to my SAS machine) is

within a certain time period then I would create the macro variable CMT which resloves to a * .

I have tried using the %if %then but was unsuccesfull.

Here is my code:

%macro comment;

%if &sysdate >='28FEB16' and <'30JAN17' %then %let cmt=*;

%mend;

%comment;

%put &cmt;

My current output from the log is:

479 %macro comment;

480 %if &sysdate >='28FEB16' and <'30JAN17' %then %let cmt=*;

481

482 %mend;

483 %comment;

SYMBOLGEN: Macro variable SYSDATE resolves to 28DEC16

484 %put &cmt;

WARNING: Apparent symbolic reference CMT not resolved.

&cmt

I want the &cmt to turin into *.

Any direction would be much apprecated.

Mike

Re: creating conditions using date range and generating a macro variable

Reeza — Wed, 28 Dec 2016 22:39:12 GMT

The following is not valid SAS code, either in macro or a data step.

&sysdate >='28FEB16' and <'30JAN17'

As is, SAS will do a text comparsion when you want a date comparison.

So perhaps something like the following, making sure to declare a global macro variable for cmt and set it to blank so you don't get previous values hanging around. For comparing dates you should use %sysevalf to make the numeric comparison. There may be another way to do the date comparisons.

%macro comment;

%global cmt;
%let cmt=;

%if %sysevalf("&sysdate"d >='28FEB2016'd) and %sysevalf("&sysdate"d<'30JAN2017'd) %then %let cmt=*;

%mend;

%comment;

%put &cmt;

Re: creating conditions using date range and generating a macro variable

Kurt_Bremser — Wed, 28 Dec 2016 22:52:50 GMT

data _null_;
if "&sysdate"d >= "28feb2016"d and "&sysdate"d < "30jan2017"d
then call symput('cmt','*');
run;

It's much easier in a data step.

Re: creating conditions using date range and generating a macro variable

Reeza — Wed, 28 Dec 2016 23:23:13 GMT

And if you use CALL SYMPUTX the third parameter creates a global macro variable.

Re: creating conditions using date range and generating a macro variable

mkeintz — Thu, 29 Dec 2016 00:01:45 GMT

Yes, it is far easier (especially when reviewing the code the next day) in a data step, but sometimes you want inline macro code that doesn't require a data step or even a user-defined macro call. This macrovar assignment can be used in open code:

%let cmt=%sysfunc(ifc(

%sysfunc(inputn(01jan2017,date9.))<%sysfunc(inputn(&sysdate,date9.)) and

%sysfunc(inputn(&sysdate,date9.))<%sysfunc(inputn(31jan2017,date9.))

,*,%str( )));

%put &=cmt;

or maybe a parameterized macro call:

%macro cmt(dat1,dat2);

%if %sysfunc(inputn(&dat1,date9.))<%sysfunc(inputn(&sysdate,date9.)) and

%sysfunc(inputn(&sysdate,date9.))<%sysfunc(inputn(&dat2,date9.))

%then *;

%else %str( )

%mend;

%let cmt=%cmt(01feb2016,31jan2017);

I know - lots and lots of %SYSFUNCs, but just for completeness.

Re: creating conditions using date range and generating a macro variable

yo1 — Thu, 29 Dec 2016 14:57:11 GMT

KurtBremser,

Thanks for your post. This gave me the answer I was looking for. The code provided is simplier to perform. The main goal for this task was to comment out certain parts of code within my main program so that certain data tables would not get overwritten in case someone needed to run the process again.

Happy Holidays.

Re: creating conditions using date range and generating a macro variable

yo1 — Thu, 29 Dec 2016 14:59:10 GMT

Hello Reeza,

Thanks for your post. Your reponse gave me the answer I was looking for. The main purpose for this task is to remove certain parts of code within a time period so that specific data tables wouldn't get overwritten.

Big thanks.

Re: creating conditions using date range and generating a macro variable

yo1 — Thu, 29 Dec 2016 15:02:29 GMT

Thanks mkeintz. Your code works as well. Its great to have variety of code for a specific task because one may run into a certain situations where one method works better (or more efficient) than others.

Happy Holidays.