topic Re: Convert dd-mmm-yy character variable to a date variable in SAS Programming

Convert dd-mmm-yy character variable to a date variable

RandiRyterman — Fri, 16 Dec 2016 15:55:29 GMT

I am a new SAS user. I imported a date in the format dd-mmm-yy that was unfortunately read as a character variable ($9). I need to convert it to a date so that I can perform logical operations on it. How do I convert this variable to a date variable?

Re: Convert dd-mmm-yy character variable to a date variable

ballardw — Fri, 16 Dec 2016 16:16:24 GMT

data example;
   x='11-FEB-16';
   date = input(compress(x,'-'),date7.);
   put date mmddyy10.;
run;

Re: Convert dd-mmm-yy character variable to a date variable

Cynthia_sas — Fri, 16 Dec 2016 16:20:03 GMT

Hi:

Here's an example I use with my students. CHARDAY is a character string and BIRTHDAY is created as the number of days from Jan 1, 1960 by using the INPUT function.

cynthia

data bday;
  length charday $9;
  infile datalines;
  input name $ charday $;
return;
datalines;
alan 01jan1960
barb 15nov1950
carl 29nov1984
dana 29sep2014
;
run;
  
data howold;
  set bday;
  birthday = input(charday,date9.);
  howold_days = (today()-birthday);
  howold_years = (today()-birthday)/365.25;
run;
  
title "After converting CHARDAY to numeric BIRTHDAY";
proc print data=howold;
  var name charday birthday howold_days howold_years;
  format birthday mmddyy10.;
run;

Re: Convert dd-mmm-yy character variable to a date variable

RandiRyterman — Fri, 16 Dec 2016 17:09:51 GMT

Thanks so much!!!

Re: Convert dd-mmm-yy character variable to a date variable

RandiRyterman — Fri, 16 Dec 2016 17:10:27 GMT

Thank you for this example!