topic Re: Calculated a weighted Average Interest Rate in SAS Programming

Calculated a weighted Average Interest Rate

Agent1592 — Mon, 05 Dec 2016 08:37:53 GMT

Dear Sas Community:

I am trying to calculate a a weighted Average Interest Rate for a company that may have several subsidiaries that borrow at different interest rates.

I have the following table:

CompanyNum	SubsidiaryNum	Amount	Rate
1	23	45000000	355
1	24	35000000	405

I want the following table:

CompanyNum	Total Amount	Weighted Average Rate
1	80000000	376.875

How can I do that using SAS Proc SQL. Any suggestions. Basically I would like to have my analysis at the company level.

Re: Calculated a weighted Average Interest Rate

chrej5am — Mon, 05 Dec 2016 09:21:38 GMT

data watch;
input CompanyNum SubsidiaryNum Amount Rate;
datalines;
1 23 45000000 355
1 24 35000000 405
;

run;

proc sql;
select
CompanyNum,
sum(Amount) as Total_Amount,
sum(Amount*Rate)/sum(Amount) as wRate
from watch
group by CompanyNum;
quit;

Re: Calculated a weighted Average Interest Rate

mkeintz — Mon, 05 Dec 2016 11:43:04 GMT

Why not use the procedure that SAS intended for this purpose? It would be easy to expand the number of vars, or request other statistics (std, var, min, max, median, various percentiles etc.)

proc summary data=have noprint nway ;

class companynum;

var rate;

weight amount;

output out=want (drop=_type_ _freq_) sumwgt(rate)=total_amount mean(rate)=wrate ;

run;