topic Re: How do I repeat a data step for all variables in a dataset with the same suffix in SAS Programming

How do I repeat a data step for all variables in a dataset with the same suffix

NCiaccia — Sat, 26 Nov 2016 00:32:39 GMT

In my dataset, I have many variables that end with the suffix _RND. For each observation in these variables, if the value is less than 0, I would like it to be 0 and if the value is greater than 3, I would like it to be 3. I've gotten so far as to be able to identify all of the variables in the dataset that end with the suffix and stored it in a list called rounded_scores (using the code below in SAS 9.4), but I dont know how to invoke this list and have the procedure repeated on each of these variables.

proc contents data=Henry out=contents(keep=name) noprint ;
Run;

proc sql noprint ;
select name into :rounded_scores separated by ' '
from contents
where upcase(name) like '%^_RND' escape '^'
;
quit;

Thanks in advance for any help you can give!

Re: How do I repeat a data step for all variables in a dataset with the same suffix

PGStats — Sat, 26 Nov 2016 04:22:50 GMT

You have done most of the work. All that is missing is:

data want;
set Henry;
array v{*} &rounded_scores;
do i = 1 to dim(v);
	v{i} = max(0, min(3, v{i}));
	end;
drop i;
run;

Re: How do I repeat a data step for all variables in a dataset with the same suffix

NCiaccia — Wed, 30 Nov 2016 16:05:23 GMT

Thanks so much for your response! That is super helpful. I am running into one problem. I have many blank observations in these variables and this array is turning anyone blank into a 3. I tried using if &rounded_score ne . in a few different places, both before the array and in the array, but I can't quite get the proper syntax to make it function.

Re: How do I repeat a data step for all variables in a dataset with the same suffix

PGStats — Wed, 30 Nov 2016 17:03:42 GMT

To keep missing values as missing, all you need is:

data want;
set Henry;
array v{*} &rounded_scores;
do i = 1 to dim(v);
	if not missing(v{i}) then v{i} = max(0, min(3, v{i}));
	end;
drop i;
run;

Re: How do I repeat a data step for all variables in a dataset with the same suffix

NCiaccia — Wed, 30 Nov 2016 17:41:55 GMT

Thank you! I also realized after I posted that I should be using v{i}. Whoops. I found that this would also work.

data want;

set Henry;

array v{*} &rounded_scores;

do i = 1 to dim(v);

if v{i} ne . then do;

v{i} = max(0, min(3, v{i}));

end;

drop i;

run;