topic How to remove unwanted character from a character string in SAS Programming

How to remove unwanted character from a character string

knveraraju91 — Sat, 19 Nov 2016 22:37:07 GMT

Dear,

In my data, the following values are present. I am not getting the output I need with my code. Please help. Thanks.

value

ALLEGRA-D /01367401/

AMOXICILLIN W/CLAVULANATE POTASSIUM

ASCORBIC ACID W/BETACAROTENE/BIOTIN/08634701/
BUDESONIDE W/FORMOTEROL FUMARATE
ESOMEPRAZOLE MAGNESIUM
HYDROCODONE COMPOUND /01224801/

output needed;

ALLEGRA-D

AMOXICILLIN W/CLAVULANATE POTASSIUM

ASCORBIC ACID W/BETACAROTENE/BIOTIN
BUDESONIDE W/FORMOTEROL FUMARATE
ESOMEPRAZOLE MAGNESIUM
HYDROCODONE COMPOUND

code:

value1=compress(value,'','d');

output getting;

ALLEGRA-D//

AMOXICILLINW/CLAVULANATE POTASSIUM

ASCORBICACID W/BETACAROTENE/BIOTIN//
BUDESONIDEW/FORMOTEROLFUMARATE
ESOMEPRAZOLEMAGNESIUM
HYDROCODONECOMPOUND//

Re: How to remove unwanted character from a character string

Patrick — Sat, 19 Nov 2016 23:55:25 GMT

Assuming the pattern you need to remove is at the end of the string and looks like /<at least one digit>/ then the following should do the job.

data sample;
  infile datalines truncover;
  length have_str want_str $60;
  input have_str $60.;
  want_str=prxchange('s/\/\d+\/\s*$//oi',1,have_str);
  datalines;
ALLEGRA-D /01367401/
AMOXICILLIN W/CLAVULANATE POTASSIUM
ASCORBIC ACID W/BETACAROTENE/BIOTIN/08634701/
BUDESONIDE W/FORMOTEROL FUMARATE
ESOMEPRAZOLE MAGNESIUM
HYDROCODONE COMPOUND /01224801/
;
run;

Re: How to remove unwanted character from a character string

mkeintz — Sun, 20 Nov 2016 01:57:47 GMT

You're halfway there. You removed all the digits, but you still have an unwanted pair '//'. Use the TRANSTRN function to eliminate those.

data want;
  set have;
  value1=compress(value,'','d');
  value1=transtrn(value1,'//','');

  /* or  value1=transtrn(compress(value,,'d'),'//','');  */
run;

Of course your program assumes the only time you have digits is when they occupy every character between a pair of slashes. You don't expect numerals anywhere else.

Here's a more specific rule. If value ends with a pair of slashes encompasing digits, remove it all. This would leave other digits in place:

data want (drop=lastchar lastword);
  set have;
  lastchar=substr(value,length(value),1);
  if lastchar='/' then do;
    lastword=scan(value,-2,'/');
    if notdigit(trim(lastword))=0 then value1=transtrn(value,cats('/',lastword,'/'),'');
  end;
  else value1=value;
run;

Regards,

Mark