topic Re: Urgent | What is wrong in my code? Using SAS 9.4 in SAS Programming

Urgent | What is wrong in my code? Using SAS 9.4

JayP — Mon, 14 Nov 2016 20:49:00 GMT

Q. Write the data step that creates a variable that should have the number of animals that are 200 kg or heavier than 200 kg.

My Ans - This code is not giving me desired results. Any modification on what is the issue ASAP will be of great help.

data animal_weight;
input animals $ weight;
datalines;
dog 19
cat 14
mice 0.25
camel 575
pigeon 0.57
cow 475
goat 18
fish 4
horse 450
donkey 330
monkey 23
lion 580
rat 0.69
rabbit 2.5
Pig 235
crow 1.8
;
run;
data sum; set animal_weight;
count=0;
array animl(*)_numeric_;
do i = 1 to 16;
if animl(i) >= 200 then count + animl(i);
proc print data=sum;
end;
run;

quit;

Re: Urgent | What is wrong in my code? Using SAS 9.4

PGStats — Mon, 14 Nov 2016 21:13:12 GMT

Revise the notion of implicit looping in the data step. This would work:

data over200; 
set animal_weight end=done;
count + (weight >= 200);
if done then output;
keep count;
run;

Explain the role of each statement to deserve a good mark.

Re: Urgent | What is wrong in my code? Using SAS 9.4

Shmuel — Mon, 14 Nov 2016 21:19:27 GMT

Your first step creates a table where each animal holds one row;

You cannot use array to deal with different rows;

You can use an array only to deal with a set of variables in the same row.

Next code will do what you ask:

data want;

set animal_weight end=eof;

retain count sum_weight 0;

if weight GE 200 then do;

sum_weight = sum(of sum_weight , weight);

count+1;

end;

if eof then put sum_weight= count=;

run;

Re: Urgent | What is wrong in my code? Using SAS 9.4

Astounding — Mon, 14 Nov 2016 21:57:21 GMT

I'm heavily biased toward using a DATA step, but I would switch for this task:

proc sql;

select count(*) from animal_weight where weight >= 200;

quit;