topic Re: using _n_ in SAS Programming

using _n_

venkatnaveen — Sun, 13 Nov 2016 17:10:20 GMT

I have:

data even_odd;

input x @@;

datalines;

257779 269998 11 20

;

run;

Modify the following data step to create a new variable named as message. The values of the

variable message must be:

‘The integer is odd’ if the variable x in the input statement has odd integer, ‘The integer is even’

if the variable x has even integer.

Should not use mod function

Re: using _n_

LinusH — Sun, 13 Nov 2016 17:30:16 GMT

o what is your question?

What have you tried?

Explore the other truncation functions...

Re: using _n_

venkatnaveen — Sun, 13 Nov 2016 17:35:24 GMT

question isi have variable x
23
456
78889
23 is odd a new variable message to be creted as odd .Similarlly
456 is even message has to be created even

Re: using _n_

PeterClemmensen — Sun, 13 Nov 2016 18:22:48 GMT

The most elegant way would be to use the MOD function, but since you rule this out, this is a possibility:

data even_odd;
   input x @@;
   datalines;
   257779 269998 1120
   ;
run;

data want(keep = x evenodd);
   set even_odd;
   y = put(x, 10.);
   
   lastdigit = substr(y,length(y),-1);

   if lastdigit in ('0', '2', '4', '6', '8') then evenodd = 'Even';
   else evenodd = 'Odd';
run;

Re: using _n_

PeterClemmensen — Sun, 13 Nov 2016 19:17:18 GMT

Or did you have something else in mind regarding your header "Using _N_" ?

Re: using _n_

Shmuel — Sun, 13 Nov 2016 20:43:08 GMT

If not using MOD function then you can check the right most digit:

string = left(x); /* convert x from numeric to characters */

digit = input(substr(string, length(string),1),1.);

if digit in ( 0 2 4 6 😎 then evn_odd = <even_message>;

else even_odd = <odd_message>;

enter the full text instead <even_message> or <odd_message>

Re: using _n_

Patrick — Sun, 13 Nov 2016 21:37:35 GMT

Like so often there are multiple ways to get it done.

proc format;
  value even_odd
    0='The integer is odd' 
    1='The integer is even'
  ;
quit;

data even_odd;
  input x @@;
  format even_odd even_odd.;
  even_odd= (int(x/2)=x/2);
  datalines;
   257779  269998  11  20
   ;
run;

Re: using _n_

venkatnaveen — Mon, 14 Nov 2016 03:53:29 GMT

Thanks sir

Re: using _n_

Ksharp — Mon, 14 Nov 2016 03:59:47 GMT

Interesting question.


  data even_odd;
   input x @@;
   y=x-int(x/10)*10;
   if y in (0 2 4 6 8) then msg='Even';
    else msg='Odd ';
   datalines;
   257779  269998  11  20
   ;
   run;