topic Re: evaluate if observations is two time in the dataset in SAS Programming

evaluate if observations is two time in the dataset

mariange8282 — Thu, 10 Nov 2016 12:37:18 GMT

Hi, I'm obtained a error because my dataset have two equal observations. I need to delete it is thats the case.

Example

_LABEL_ X1 X2 X3

Obs1 1 2 3

Obs2 4 5 6

Obs1 7 8 9

Obs3 4 5 6

I need to delete Obs1 because its repeat

Any idea?

Re: evaluate if observations is two time in the dataset

PeterClemmensen — Thu, 10 Nov 2016 12:40:39 GMT

Like this?

data have;
   input _LABEL_ $ X1 X2 X3;
   datalines;
Obs1 1 2 3 
Obs2 4 5 6 
Obs1 7 8 9 
Obs3 4 5 6 
;

proc sort data = have;
   by _LABEL_;
run;

data want;
   set have;
   by _LABEL_;
   if first._LABEL_;
run;

Re: evaluate if observations is two time in the dataset

PeterClemmensen — Thu, 10 Nov 2016 12:41:40 GMT

Or do you need to delete both Obs1 observations?

Re: evaluate if observations is two time in the dataset

PeterClemmensen — Thu, 10 Nov 2016 12:42:48 GMT

In that case

data want;
   set have;
   by _LABEL_;
   if first._LABEL_ = last._LABEL_;
run;

Re: evaluate if observations is two time in the dataset

Kurt_Bremser — Thu, 10 Nov 2016 13:16:30 GMT

@mariange8282 wrote:

Hi, I'm obtained a error because my dataset have two equal observations. I need to delete it is thats the case.

Example

_LABEL_ X1 X2 X3

Obs1 1 2 3

Obs2 4 5 6

Obs1 7 8 9

Obs3 4 5 6

I need to delete Obs1 because its repeat

Any idea?

Since the "Obs1" observations contain different data in the other columns, the question arises: which values need to be kept?

Simply sorting away with nodupkey might lose valuable information.

Re: evaluate if observations is two time in the dataset

Loko — Thu, 10 Nov 2016 13:16:38 GMT

Hello,


data have;
   input _LABEL_ $ X1 X2 X3;
   datalines;
Obs1 1 2 3 
Obs2 4 5 6 
Obs1 7 8 9 
Obs3 4 5 6 
;
run;

data want;
if _n_=1 then
 do;
 	declare hash h(dataset:"have", multidata :'Y');
	h.definekey('_LABEL_');
	h.definedata(all:'YES');
	h.definedone();
 end;

do until (last);
  set have end=last;
  rc=h.find();
  if h.find_next() ne 0 then output;
end;

drop rc;
run;

Re: evaluate if observations is two time in the dataset

Ksharp — Fri, 11 Nov 2016 11:21:21 GMT


data have;
   input _LABEL_ $ X1 X2 X3;
   datalines;
Obs1 1 2 3 
Obs2 4 5 6 
Obs1 7 8 9 
Obs3 4 5 6 
;
run;

data want;
if _n_=1 then do;
 if 0 then set have;
 	declare hash h();
	h.definekey('_LABEL_');
	h.definedone();
end;
set have ;
if h.check()=0 then delete;
 else h.add();
run;