topic Re: deleting columns in SAS Programming

deleting columns

Jahanzaib — Thu, 10 Nov 2016 03:18:31 GMT

I have data which include around 20-25 columns. I want to keep only first 7 columns and delete the remaining. How can i do that?

Re: deleting columns

Jagadishkatam — Thu, 10 Nov 2016 03:48:17 GMT

Please get the details of the variables in the dataset by

proc contents data=x out=vars;
run;

After this sort the data by order of the variables with VARNUM

proc sort data=vars;
by varnum;
run;

create a macro variable keep from proc sql

proc sql;
select name into:keep from vars where varnum<=7;
quit;

%put &keep;

Use this keep macro variable to keep only the required variables.

Re: deleting columns

RahulG — Thu, 10 Nov 2016 03:57:40 GMT

%let no_of_col=7;
/* Sample dataset cars considered for code */
data cars;
set sashelp.cars;
run;

/* column list extracted */
proc contents data=cars out=column_nm varnum;
run;

proc sort data=column_nm out=col_nm_sorted(keep = libname memname name);
by varnum;
run;

data filtered_col;
set col_nm_sorted(obs=&no_of_col);
run;



proc sql noprint;
select name into :_col_name separated by ' '
from filtered_col;
quit;
%put &_col_name ;

data want;
set cars (keep = &_col_name);
run;

I have taken work.cars as an input dataset and kept first 7 columns

Re: deleting columns

RW9 — Thu, 10 Nov 2016 09:21:51 GMT

The simplest way is to use list operator in SAS:

data want;
  set have (keep=<first>--<last>);
run;

Replace <first> with the variable to start from and <last> with the last one - you of course know what these are as it is your data. I would not rely on order of columns in the dataset - that can change very easliy and then you get different results.