topic Re: how to remove unwanted characters and the values after the characters in SAS Programming

How to remove unwanted characters and the values after those characters

knveraraju91 — Mon, 31 Oct 2016 05:35:44 GMT

Dear,

In my data some values contain "!!" characters in the middle of values. I need to remove the characters and the values after the characters. Thank you

data

term

Subject did not drink 50% of the meal!! Chicken

output needed;

Subject did not drink 50% of the meal

how to remove unwanted characters and the values after the characters

knveraraju91 — Mon, 31 Oct 2016 05:37:06 GMT

Dear,

In my data some values contain "!!" characters in the middle of values. I need to remove the characters and the values after the characters. Thank you

data

term

Subject did not drink 50% of the meal!! Chicken

output needed;

Subject did not drink 50% of the meal

Re: How to remove unwanted characters and the values after those characters

Reeza — Mon, 31 Oct 2016 06:11:28 GMT

Scan function.

Re: how to remove unwanted characters and the values after the characters

Kurt_Bremser — Mon, 31 Oct 2016 07:19:04 GMT

I'd try the tranwrd() function, and then scan():

data have;
infile cards truncover;
input term $100.;
cards;
Subject did not drink 50% of the meal!! Chicken
;
run;

data want;
set have;
term = tranwrd(term,"!!","|");
term = scan(term,1,"|");
run;

Since one can only use single characters as delimiters in scan().

Re: how to remove unwanted characters and the values after the characters

PeterClemmensen — Mon, 31 Oct 2016 07:24:53 GMT

Try this

data test;
string='Subject did not drink 50% of the meal!! Chicken';
newstring = substr( string,1,index(string,'!!') - 1);
run;

Re: How to remove unwanted characters and the values after those characters

RW9 — Mon, 31 Oct 2016 09:47:15 GMT

Sounds like a job for the compress function - which removes given characters:

data have;
  infile cards truncover;
  input term $100.;
  term2=compress(term,"!");
cards;
Subject did not drink 50% of the meal!! Chicken
;
run;

Re: how to remove unwanted characters and the values after the characters

Patrick — Mon, 31 Oct 2016 09:52:05 GMT

If you just want everything before the first exclamation mark then the scan() function on its own should do.

Not sure why @Kurt_Bremser believes that duplicates need replacement for your use case.

data have;
  infile cards truncover;
  input term $100.;
  cards;
Subject did not drink 50% of the meal!! Chicken
;
run;

data want;
  set have;
  term = scan(term,1,"!");
run;

Re: how to remove unwanted characters and the values after the characters

Kurt_Bremser — Mon, 31 Oct 2016 11:47:47 GMT

@Patrick wrote:

.....

Not sure why @Kurt_Bremser believes that duplicates need replacement for your use case.

Well, if you have a single exclamation mark in the text before the doubles ...

Re: how to remove unwanted characters and the values after the characters

Patrick — Wed, 02 Nov 2016 11:50:30 GMT

@Kurt_Bremser

But didn't the OP tell us that he just wants "everything" from the beginning up to the first exclamation mark? So what do we care about any futher exclamation marks in the string. Based on your code I must be missing something.

Re: how to remove unwanted characters and the values after the characters

Kurt_Bremser — Wed, 02 Nov 2016 12:24:28 GMT

Look at the log from this:

data _null_;
term = 'Subject complains! Subject did not drink 50% of the meal!! Chicken';
term1 = tranwrd(term,"!!","|");
term1 = scan(term,1,"|");
term2 = scan(term,1,"!");
put term1=;
put term2=;
run;

The OP stated that the delimiter is a sequence of two exclamation marks.

Granted that I may be a little overcautious here, but better safe than sorry.

Re: how to remove unwanted characters and the values after the characters

Patrick — Thu, 03 Nov 2016 09:52:54 GMT

@Kurt_Bremser

Thanks. I did miss that the delimiter is TWO pipes. That explains what your'e doing.

Here a variant using RegEx

data have;
  term = 'Subject complains!! Subject did not drink 50% of the meal!! Chicken';
  output;
  term = 'Subject complains! Subject did not drink 50% of the meal!! Chicken';
  output;
  term = 'something';
  output;
run;

data want;
  set have;
  if 0 then want_str=term;
  want_str=prxchange('s/(!{2}.*)//oi',1,term);
run;