topic Re: Changing the length of a character variable in SAS Programming

Changing the length of a character variable

WesBarris — Fri, 23 Sep 2011 16:56:46 GMT

Is there a way to change the length of a character variable? I am using proc import to import

data from a .dbf file. One of the data fields is character and 5 characters wide. I would like

to later assign larger character strings to this variable. To do this I create a new variable in a

separate data step to do this. Is there more elegant way?

Changing the length of a character variable

art297 — Fri, 23 Sep 2011 17:03:19 GMT

Include a length statement before your set statement. e.g.,

data have;

set sashelp.class;

run;

proc contents;

run;

data have;

length Name $30;

set have;

if _n_ eq 1 then Name="Rumpelstiltskin";

run;

proc contents;

run;

Changing the length of a character variable

SASJedi — Fri, 23 Sep 2011 18:09:12 GMT

This is a perfect opportunity to leverage some PROC SQL 🙂 Assuming your imported data set is "lib.have" and the name of the character variable you want to modify is "TextVar", this should work for you:

 
proc sql;
alter table lib.have
  modify TextVar char(20) format=$20. informat=$20.;
quit;

Changing the length of a character variable

WesBarris — Fri, 23 Sep 2011 19:12:59 GMT

Thanks Art. That is what I was looking for. However, in order for me to make this

work I hand to change "length" to "format". Using "length" didn't allow me to reset

any character variable to hold longer strings. Here is some sample code showing

what I had to do:

data have;

format Name $30.;

set have;

if _n_ eq 1 then Name="Rumpelstiltskin";

run;

Changing the length of a character variable

art297 — Fri, 23 Sep 2011 19:26:56 GMT

Out of curiosity, what version of SAS are you using and on which platform?

For me, on 9.2 on an XP, both length and format change the other accordingly.

Changing the length of a character variable

WesBarris — Fri, 23 Sep 2011 19:29:27 GMT

Hi Art,

We are running SAS 9.2 on Windows server 2008.

Changing the length of a character variable

art297 — Fri, 23 Sep 2011 19:34:59 GMT

When you used the length statement did you make sure that it wasn't expressed as a format? i.e., did you use $30 and NOT $30. ?

Changing the length of a character variable

WesBarris — Fri, 23 Sep 2011 19:42:46 GMT

That is correct. The length statement I tried was:

length wingband $6;

When I changed that to:

format wingband $6.;

it worked for me.

Changing the length of a character variable

art297 — Fri, 23 Sep 2011 19:45:36 GMT

Glad it worked! Unless someone more knowedgeable than me can quickly provide an answer regarding why the length statement didn't work, I'll see if I can find out.

Changing the length of a character variable

DLing — Fri, 23 Sep 2011 20:48:56 GMT

All of my testing with SAS 9.1.3 PC and SAS 9.2 Unix shows length statement working properly. Of course, the length statement needs to be at the beginning of the data step prior to the set statement.

I am at a loss to understand why it wouldn't work without seeing the actual program and logs.

Changing the length of a character variable

SASJedi — Sat, 24 Sep 2011 02:41:03 GMT

It's probable that, when you imported the data from dBase, PROC IMPORT assigned a permanent format of $5. to the NAME variable. If that is true, this code:

data have;
  length Name $ 30;
  set have;
  if _n_ eq 1 then Name="Rumpelstiltskin";
run;

actually DID change the length of the variable, but it was only displaying 5 characters by default, because of the format. Subsequently running this code:

data have;
  format Name $30.;
  set have;
  if _n_ eq 1 then Name="Rumpelstiltskin";
run;

would replace the $5. format with $30. and allow the extra characters to display.

This PROC SQL solution simultaneously modifies both the length of the variable and the format:

proc sql;
alter table lib.have
  modify TextVar char(20) format=$20.;
quit;

Alternatively, you could use both LENGTH and FORMAT statements in the DATA step code to accomplish the same result:

data have;
  length Name $30;
  format Name $30.;
  set have;
  if _n_ eq 1 then Name="Rumpelstiltskin";
run;

Changing the length of a character variable

WesBarris — Sun, 25 Sep 2011 20:56:18 GMT

Since the data is being imported from a dBase file your explanation must be correct.

Thanks for your help.

Changing the length of a character variable

Tom — Sun, 25 Sep 2011 21:35:06 GMT

This is one of my pet peeves with SAS's implementation of importing data from databases. They always attach both a format and an informat to character variables. As you have seen this can cause a number of headaches when you start combining that data with other datasets.

In general permanently attaching the $ format to a character variable adds nothing of value.

The only way I know to remove these is to use the FORMAT (or INFORMAT) statement with a variable list, but without a format.

data sasfile ;

set dbfile ;

format _character_ ;

run;

Changing the length of a character variable

art297 — Sun, 25 Sep 2011 22:14:57 GMT

Wes,

If you have such a file that was imported from dBase, and doesn't contain confidential info and hasn't been modified, I'd appreciate your sending me a copy (to art297 at rogers dot com). I'm still investigating the matter, but have never confronted a "permanent format". I would bet that there is still more to learn.

Changing the length of a character variable

Tom — Sun, 25 Sep 2011 22:35:19 GMT

Art -

"Permanent formats" are just formats that are permanently attached because they are defined in the datasets. As opposed to formats that you temporarily attach during a procedure by using a format statement.

- Tom

Changing the length of a character variable

art297 — Sun, 25 Sep 2011 22:40:23 GMT

Tom,

Thanks for enlightening me! What I am concerned about is NOT that one has to define desired length and format changes but, instead, the behavior of the SAS Explorer. When one only changes the length, it shows that both the length, format and informat has changed.

That wouldn't qualify as a "bug" but, frankly, it is simply wrong! Why give a user incorrect information?

Changing the length of a character variable

SASJedi — Mon, 26 Sep 2011 02:34:38 GMT

You can use PROC DATASETS to modify variable characteristics, including formats. Here is some sample code to play with:

 
data test;
  set sashelp.class;
  format Name $8. weight z5.1;
run;
title "Formatted values";
proc print; run;

/*Get a list of variable names in a macro variable*/
proc sql noprint;
select Name into :Varnames separated by ' '
  from dictionary.columns
  where libname='WORK' and memname='TEST';
quit;

/*Remove formats from all the variables*/
proc datasets library=work nolist;
  modify test;
  format &varnames;
quit;
title "After formats removed";
proc print; run;

Changing the length of a character variable

Tom — Mon, 26 Sep 2011 05:28:55 GMT

Art -

I think that the problem is that ViewTable does not distinguish between the formats that are defined in the dataset and those that it is using because of default behaviour. I would prefer that it just leave the format/informat attributes empty in that screen, as they are in the dataset. If they must put in a default value then it should be marked in someway to distinguish between that and the value of the attribute that is in the dataset's metadata.

Changing the length of a character variable

Ksharp — Mon, 26 Sep 2011 08:36:06 GMT

SASJedi.

There is no need to use dictionary table any more , directly use variable list _all_;

data test;

set sashelp.class;

format Name $8. weight z5.1;

run;

title "Formatted values";

proc print; run;

/*Remove formats from all the variables*/

proc datasets library=work nolist;

modify test;

format _all_;

quit;

title "After formats removed";

proc print; run;

Ksharp

Re: Changing the length of a character variable

Sir_Highbury — Fri, 24 Jun 2016 12:07:49 GMT

Dear experts,

on the basis of our explanation I am trying co change my data as it follows:

1. increase the length of the variable:

proc sql;
alter table DC.input_analysis_res
modify Default_value char(20) format=$20. informat=$20.;
quit;

2. insert the string "No_def_v"
/* set unique value in case of default value missing */
data DC.input_analysis_res; set DC.input_analysis_res; if Default_value in ('',' ','-','.') then Default_value='No_def_v';run;

What is wrong with it? I got in the new varibale only the first two digits, i.e. "No" without the rest "_def_v"