topic Re: how to convert 12december2015 to sas date value? in SAS Programming

how to convert 12december2015 to sas date value?

dpa — Thu, 20 Oct 2016 09:55:30 GMT

Please can anyone guide me how to do it apart from stripging the value to ddmmmyyyy format?

Re: how to convert 12december2015 to sas date value?

Loko — Thu, 20 Oct 2016 10:19:38 GMT

I don't know if there is an informat which can read the value, but you can adapt it so ANYDTDTE can read it.

data _null_;
x='12december2015';
y=compress(x,,'d')||' '||substr(x,1,2)||', '||scan(x,-1,,'ab');

z=input(y,ANYDTDTE21.);

put z date9.;
run;

Re: how to convert 12december2015 to sas date value?

RW9 — Thu, 20 Oct 2016 10:26:41 GMT

Another method:

data want;
  x='12december2016';
  thedate=input(cat(substr(x,1,2),upcase(substr(x,3,3)),substr(x,11,4)),date9.);
  format thedate date9.;
run;

Re: how to convert 12december2015 to sas date value?

dpa — Thu, 20 Oct 2016 10:42:23 GMT

Please can you explain 'ab' in scan function?

Re: how to convert 12december2015 to sas date value?

Ksharp — Thu, 20 Oct 2016 11:17:03 GMT

data _null_;
x='12december2015';
y=input(x,anydtdte32.);

put y= date9.;
run;

Re: how to convert 12december2015 to sas date value?

dpa — Thu, 20 Oct 2016 12:04:41 GMT

Thank you for your time and answer but only problem with this is you have to change length for year extraction for diffrent month

Re: how to convert 12december2015 to sas date value?

dpa — Thu, 20 Oct 2016 12:05:51 GMT

HI Ksharp

This one I did try but somehow gives missing value

Re: how to convert 12december2015 to sas date value?

Loko — Thu, 20 Oct 2016 12:23:05 GMT

Hello,

you can check here the modifiers role within scan function.

http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a000214639.htm

Re: how to convert 12december2015 to sas date value?

RW9 — Thu, 20 Oct 2016 12:24:32 GMT

Yes, sorry, didn't think of that, here is an update to catch this:

data want;
  x='12december2016';
  thedate=input(cat(substr(x,1,2),upcase(substr(x,3,3)),substr(x,lengthn(x)-3,4)),date9.);
  format thedate date9.;
run;

Re: how to convert 12december2015 to sas date value?

Kurt_Bremser — Thu, 20 Oct 2016 13:23:47 GMT

@dpa wrote:

HI Ksharp

This one I did try but somehow gives missing value

Please show which input string results in a missing value.

Re: how to convert 12december2015 to sas date value?

ballardw — Thu, 20 Oct 2016 14:05:50 GMT

@Kurt_Bremser

I get the same missing result using SAS 9.2 running your posted example.

Re: how to convert 12december2015 to sas date value?

dpa — Thu, 20 Oct 2016 14:06:52 GMT

data _null_;

252 x='12december2015';

253 y=input(x,anydtdte32.);

254

255 put y= date9.;

256 run;

y=.

log copy and pasted here

Re: how to convert 12december2015 to sas date value?

ChrisNZ — Fri, 21 Oct 2016 01:07:12 GMT

27         data _null_;
28           x='12december2015';
29           y=input(x,anydtdte32.);
30           put y= date9.;
31         run;

y=12DEC2015 with SAS9.4 on WINx64
y=12DEC2015 with SAS9.4 on LINx64
y=.                    with SAS9.3 on Z/OS

This works in 9.3:

data _null_;
X='12december2015';
Y=input(prxchange('s/(\d{2}\w{3})\w*(\d{4})/$1$2/',1,X),date9.);
put Y= date9.;
run;