topic Re: How to set subsequent values to missing and keep first occurence in SAS Programming

How to set subsequent values to missing and keep first occurence

SimRock — Mon, 10 Oct 2016 23:30:53 GMT

Hi I am trying to keep the first occurence of a variable and set the subsequent values of the variables to missing

My data looks like this

Data have;

input id time AMI;

datalines;

1 1 0

1 2 0

1 3 1

1 4 0

2 1 1

2 2 0

2 2 1

2 4 0

run;

I would like my data to look like this

ID time AMI

1 1 0

1 2 0

1 3 1

1 4 .

2 1 1

2 2 .

2 4 .

Basically, I only want to assess the first occurence of AMI

Thank you

Re: How to set subsequent values to missing and keep first occurence

Shmuel — Tue, 11 Oct 2016 00:53:32 GMT

Assuming data is sorted by ID you can do:

data want;

set have;

by ID;

retain flag; drop flag;

if first.id then flag=0;

if flag=1 then ami=.;

if ami=1 and flag=0 then flag=1;

run;

Re: How to set subsequent values to missing and keep first occurence

PGStats — Tue, 11 Oct 2016 01:43:26 GMT

I would do:

data want;
do until(last.id);
    set have; by id;
    if AMImet 
        then call missing(newAMI);
        else newAMI = AMI;
    output;
    if AMI then AMImet = 1;
    end;
drop AMI AMImet; rename newAMI=AMI;
run;

Re: How to set subsequent values to missing and keep first occurence

SimRock — Tue, 11 Oct 2016 01:57:21 GMT

Thank you very Shmuel. It works perfectly

Best

Re: How to set subsequent values to missing and keep first occurence

SimRock — Tue, 11 Oct 2016 01:58:42 GMT

Thank you very PGStats. Your codes works awesome too.

Thanks so much

Best