topic Re: Proc Summary Help! in SAS Programming

Proc Summary Help!

Milouda — Mon, 29 Aug 2016 12:27:14 GMT

I intend to create the following statistics for some continuous variable. I used Proc summary as follow

proc summary data=&dataset nway completetypes;
   class &grp/ preloadfmt;
   var &continuous;
   output out=continuous2(drop=_type_);							
   run;

this was my output.

ths

Is there any way to add to the same table the quantiles(Q1, Median and Q3)?

thanks

Re: Proc Summary Help!

LinusH — Mon, 29 Aug 2016 12:29:41 GMT

http://support.sas.com/documentation/cdl/en/proc/68954/HTML/default/n1qnc9bddfvhzqn105kqitnf29cp.htm#n11nn4xu6p9wvjn1lh60wtvvn538

Re: Proc Summary Help!

Milouda — Mon, 29 Aug 2016 12:33:07 GMT

I tried by listing the keywords for the statistics I want, no luck. It only produces statistics for one variable.
What is wrong in my code?

Re: Proc Summary Help!

data_null__ — Mon, 29 Aug 2016 12:43:38 GMT

You can add output statements for each new statistic and the combine, this make the syntax easy.

I used to do that but with PROC MEANS STACKODS I prefer that option. While the data structure is not the same it is equally useful.

proc summary nway data=sashelp.class;
   class sex;
   var _numeric_;
   output out=stats;
   output out=median median=;
   output out=q1 q1=;
   output out=q3 q3=;
   run;
data stats;
   set stats median q1 q3 indsname=indsname;
   by sex;
   if missing(_stat_) then _stat_=scan(indsname,-1,'.');
   run;
proc print;
   run;
ods exclude all;
proc means data=sashelp.class n mean std min max median q1 q3 nway stackods;
   class sex;
   ods output summary=summary;
   run; 
ods exclude none;
proc print;
   run;

Re: Proc Summary Help!

Ksharp — Tue, 30 Aug 2016 03:33:25 GMT


   proc univariate data=sashelp.class outtable=want noprint;
   class sex;
   var age weight height;
   run;
   proc sort data=want; by sex _var_;run;
   proc print noobs label;run;

Re: Proc Summary Help!

data_null__ — Tue, 30 Aug 2016 11:45:49 GMT

@Ksharp wrote:

   proc univariate data=sashelp.class outtable=want noprint;
   class sex;
   var age weight height;
   run;
   proc sort data=want; by sex _var_;run;
   proc print noobs label;run;

PROC UNIVARIATE does not support PRELOADFMT and has other CLASS statement limitations.