topic Re: How do I perform a conditional substitution using PRXCHANGE? in SAS Programming

How do I perform a conditional substitution using PRXCHANGE?

jylo — Mon, 08 Aug 2016 21:31:32 GMT

I'm trying to write to conditionally substitute portions of a text string. For example, if I have:

A123

AX345

B456

BY789

I want the values in my data set to be:

AX123

AX345

BY456

BY789

Is there a way to accomplish this in one prxchange statement?

(Using SAS 9.4.)

Re: How do I perform a conditional substitution using PRXCHANGE?

Ksharp — Tue, 09 Aug 2016 04:01:53 GMT

Assuming the data is just like what you posted:


data have;
input x $20.;
cards;
A123
AX345
B456
BY789
;
run;
data have;
 set have;
 group=first(x);
 n=length(x);
run;
proc sort data=have;
 by group n;
run;
data want;
 do until(last.group);
  set have;
  by group;
 end;
 _x=x;
 do until(last.group);
  set have;
  by group;
  x=scan(_x,1,,'d')||scan(x,-1,,'kd');
  output;
 end;
 drop _x group n;
run;

Re: How do I perform a conditional substitution using PRXCHANGE?

RW9 — Tue, 09 Aug 2016 08:40:56 GMT

Depends on several factors, is it just two, then:

data have;
  input x $20.;
cards;
A123
AX345
B456
BY789
;
run;
data want;
  set have;
  x=ifc(substr(x,1,1)="A",cats("AX",compress(x," ","kd")),cats("BY",compress(x," ","kd")));
run;

If its more, but you know them up front then:

data want;
  set have;
  select(substr(x,1,1));
    when ("A") x=cats("AX",compress(x," ","kd"));
    when ("B") x=cats("BY",compress(x," ","kd"));
    otherwise;
  end;
run;

If you don't know them up front then you will need to provide the logic to populate them, I.e. you could have AX and AY?

Re: How do I perform a conditional substitution using PRXCHANGE?

jylo — Fri, 12 Aug 2016 15:07:53 GMT

The second alpha character is always known.

Is there a way to do this using PRXCHANGE?

Re: How do I perform a conditional substitution using PRXCHANGE?

Ksharp — Sat, 13 Aug 2016 04:25:56 GMT

data have;
input x $ y $;
length want pid $ 40;
pid=cats('s/^([a-z])[a-z]*(\d+)/$1',y,'$2/i');
want=prxchange(pid,1,x);
cards;
A123 X
AX345 X
B456 Y
BY789 Y
;
run;