topic Re: How to read specific information from Tweet data in SAS Programming

How to read specific information from Tweet data

Attyslogin — Fri, 05 Aug 2016 21:03:25 GMT

note : raw data line are actually different twitter comments. Need to fetch only those data which has special character (with character) as shown in output and those comment does not contains special character then make it null.

Raw data

@nice#Greatwork@fake

very nice portal ncs

Good portal @hatsoff

output needed :

@nice

#Greatwork

@fake

null

@hatsoff

Re: How to read specific information from Tweet data

Reeza — Fri, 05 Aug 2016 21:06:39 GMT

Look at the SCAN() function including the third parameter, which allows you specify the delimiter.

Re: How to read specific information from Tweet data

Attyslogin — Fri, 05 Aug 2016 21:15:13 GMT

can you show me the exact code ?

Re: How to read specific information from Tweet data

Reeza — Fri, 05 Aug 2016 21:47:51 GMT

Here's a fully worked example. Specify your delimiters as needed, make sure to include spaces in there if required.

http://blogs.sas.com/content/iml/2016/07/11/break-sentence-into-words-sas.html

I don't think these will give you a NULL value, but if you really need it add in a check if the number of words is 0 then output a null record.

Re: How to read specific information from Tweet data

error_prone — Mon, 08 Aug 2016 10:31:22 GMT

A not to complex regular expression and call prxnext can solve the problem:

data work.have;
   length lot $ 100;
   input;

   lot = trim(_infile_);

   datalines;
@nice#Greatwork@fake
very nice portal ncs 
Good portal @hatsoff
;
run;


data work.want;
   set work.have;
   length 
      word $ 100
      rx start p l 8
   ;
   retain rx;

   if _n_ = 1 then do;
      rx= prxparse('/([@#]\w+)/i');
   end;

   start = 1;
   
   call prxnext(rx, start, -1, lot, p, l);
   do while (p > 0);
      word = substr(lot, p, l);
      output;
      call prxnext(rx, start, -1, lot, p, l);
   end;

   if missing(word) then do;
      word = 'null';
      output;
   end;

   keep word;
run;