topic Text Date to SAS Date in SAS Programming

Text Date to SAS Date

sks — Tue, 18 Oct 2011 17:29:05 GMT

Hi,

I have a text date in the format '10Jan2011', I need to find the last day of the month, for the given date. How do I convert the text date into sas date and then find the last day of the month.

Thank You for all your help

Shri

Text Date to SAS Date

art297 — Tue, 18 Oct 2011 17:37:17 GMT

I think you are looking for:

data have;

informat date $9.;

input date;

cards;

10Jan2011

;

data want;

set have (rename=(date=textdate));

format date last_day_of_month date9.;

date=input(textdate,date9.);

last_day_of_month=intnx('month',date,0,"E");

run;

Text Date to SAS Date

Tom — Tue, 18 Oct 2011 17:58:47 GMT

If you have it as a macro variable then you can use it as date literal.

%let textdate=10JAN2011;

%let endmonth = %sysfunc(intnx(month,"&textdate"d,0,E),date9.);

%put &textdate &endmonth;

10JAN2011 31JAN2011

Text Date to SAS Date

sks — Tue, 18 Oct 2011 18:15:08 GMT

Tom/ Art

Both your responses are very helpful, but I am getting 2 parameters from the prompt, a month (text value from selected from a drop down menu) and year (a date value formatted as a year) Now I have to concatenate these to values to get the month and year and then find the last day of the month.

For eg.

user selects January for the month and 2011 for the year

then I need to get 1/31/2011

Here is the code I have

%let SEL_MONTH=February;
%let SEL_YEAR=01Jan2011;
data _null_;
length fmonth $15. dmonth $15.;
call symput('dyear',put("&sel_Year"d,year4.));
dmonth="'"||"01"||substr("&sel_Month",1,3)||"&dyear"||"'";
call symput('dmonth',(dmonth));

ddate=input('&dmonth', date9.);
format ddate date9.;
call symput('ddate',ddate);

lastDay=intnx('Month' ,"&dmonth"d,0,E);
call symput('lastday',"'"||put(lastday,mmddyyS10.)||"'");
run;
%put &sel_Month;
%put &dYear;
%put &lastday;
%put &ddate;
%put &dmonth;

I am not sure what I am doing wrong, but I am not getting the last day of the month.

Shri

Text Date to SAS Date

art297 — Tue, 18 Oct 2011 19:10:05 GMT

If your inputs are macro variables, and you only need another macro variable showing the end of the month, why not use something like:

%let SEL_MONTH=February;

%let SEL_YEAR=01Jan2011;

%let endmonth = 01%sysfunc(substr(&sel_month,1,3))%sysfunc(substr(&sel_year,6,4));

%let endmonth = %sysfunc(intnx(month,"&endmonth"d,0,E),date9.);

%put &endmonth;

Text Date to SAS Date

sks — Fri, 21 Oct 2011 19:29:40 GMT

Thanks Art, for the Macro suggestion, it is very helpful and has helped in what I have been trying to do.

Shri