topic Re: Filtering columns in SAS Programming

Filtering columns

VanDalucas — Mon, 04 Jul 2016 08:27:43 GMT

Hi,

I have a big data set with more than 4000 columns and need to keep columns that have specific sequence of characters in their name (e.g. "_US_"). Can I that using wildcards in "Keep" statement?

thank you

Re: Filtering columns

arodriguez — Mon, 04 Jul 2016 08:36:14 GMT

If they start with the same sequence of characters you could say something like _US_:.
If they are all together in the dataset you could say "all variables between X and Y" with X--Y.

Re: Filtering columns

Loko — Mon, 04 Jul 2016 09:16:12 GMT

Hello,

If the sequence is in the middle of the character name you can select those variable in a macro statement separated by space and

use this macro variable in a keep statement.

For doing this operation you shall use the dictionary table - vcolumn:

proc sql;
select name into :vr separated by ' '
from sashelp.vcolumn
where libname eq 'SASHELP' and memname eq 'CLASS'
and name like '%h%';
quit;

data want;
set sashelp.class;
keep &vr;
run;

Re: Filtering columns

stat_sas — Mon, 04 Jul 2016 09:31:59 GMT

Hi,

On a similar pattern as per @Loko suggestion:

proc contents data=have out=vars(keep=name);
run;

proc sql;
select name into :vars_needed separated by ' '
from vars
where find(name,"_US_")>0;
quit;

%put &vars_needed;

Re: Filtering columns

VanDalucas — Mon, 04 Jul 2016 13:27:03 GMT

I really thank all of you for you replies,

The solution using proc sql worked fine,

(I was just wondering if a more ''complex'' KEEP statement could do the job but it seems there is no such possibility)

Re: Filtering columns

LinusH — Mon, 04 Jul 2016 14:29:16 GMT

Having 4000 columns is usually not a very user/programming friendly structure. You'll probably encounter other similar problems down the road.
Consider transposing your data to long format, then you'll be able to do more clever things with simpler filtering and grouping.