topic Re: Flag first diagnosis beginning with "S06" in SAS Programming

Flag first diagnosis beginning with "S06"

BTAinRVA — Wed, 15 Jun 2016 21:24:50 GMT

I have a table with columns for person_id, Encounter_Date, Diagnosis1-10, and DxCode. How can i flag the first DxCode that starts with "S06" for each separate person_id and Encounter_Date?

Thanks,

Brian

Re: Flag first diagnosis beginning with "S06"

PGStats — Wed, 15 Jun 2016 21:52:02 GMT

If you don't mind sorting your data:

proc sort data=have; by person_id Encounter_Date DxCode; run;

data want;
set have;
by person_id Encounter_Date DxCode;
flag = first.DxCode and DxCode =: "S06";
run;

Re: Flag first diagnosis beginning with "S06"

Reeza — Wed, 15 Jun 2016 22:28:46 GMT

Starts with makes it a bit more difficult.

I think you'll have to create an array of the diags and loop over them unfortunately. If it was full code I would use WHICHC Function.

Re: Flag first diagnosis beginning with "S06"

Astounding — Wed, 15 Jun 2016 23:08:54 GMT

Here's what I think you are looking for:

proc sort data=have; by person_id Encounter_Date; run;

data want;
set have;
by person_id Encounter_Date;
if first.Encounter_Date then do;
   flag=0;
   S06_found=0;
end;
retain flag S06_found;
if DxCode =: 'S06' then do;
   S06_found + 1;
   if S06_found=1 then flag=1;
   else flag=0;
end;
else flag=0;
drop S06_found;
run;

It gets a little tricky because there can be multiple, different Dx Codes that begin with S06 on the same date.

Re: Flag first diagnosis beginning with "S06"

BTAinRVA — Thu, 16 Jun 2016 21:26:56 GMT

PG,

Thanks for the reply. I was able to get it to work with some minor tweaks (needed because i didn't explain my problem well enough).

Brian