topic Re: Using a "if" statement after a do loop to filter out information in SAS Programming

Using a "if" statement after a do loop to filter out information

johntan_123 — Tue, 07 Jun 2016 02:02:24 GMT

Hi All,

The following SAS code creates a dataset list that contains the variable snapshot (in yyyymm format) from 200309 to 201603. There is a "if" condition that is supposed to result in only the snapshots 200309 to 201506 being populated. However, the "if" condition does not work. Please advise on why this is so. Any help would be much appreciated. Thanks!

%let   strte=200309;
%let   ende=201506;

%macro download;

data list(drop=i);
	do i=0 to 150;
		index=i;
		snapshot=put(intnx('month',input("&strte.",yymmn6.),i),yymmn6.);
		output;
	end;
	if snapshot<="&ende.";
run;


%mend download;


%download;

Re: Using a "if" statement after a do loop to filter out information

PGStats — Tue, 07 Jun 2016 02:50:05 GMT

You must make the OUTPUT statement conditional

%let   strte=200309;
%let   ende=201506;

%macro download;

data list(drop=i);
	do i=0 to 150;
		index=i;
		snapshot=put(intnx('month',input("&strte.",yymmn6.),i),yymmn6.);
		if snapshot<="&ende." then output;
	        end;
run;


%mend download;


%download;

OUTPUT is an executable statement. You can't cancel its effect with later statements.

Re: Using a "if" statement after a do loop to filter out information

RW9 — Tue, 07 Jun 2016 08:46:16 GMT

Why is this in a macro, there is no need for it. You can also write your code so that the do loop executes only for the number of intervals between the two items (note, if you avoided putting data in macro variables your life would also be much easier). So your code can actually be written as:

%let   strte=200309;
%let   ende=201506;
data list(drop=i);
  do i=0 to intck('month',input("&strte.",yymmn6.),input("&ende",yymmn6.));
    index=i;
    snapshot=put(intnx('month',input("&strte.",yymmn6.),i),yymmn6.);
    output;
  end;
run;

This will then only loop for the needed number of iterations and outputs each time, whereas the do with and if statement will run 150 times regardless of how many times it needs to.

Re: Using a "if" statement after a do loop to filter out information

ballardw — Tue, 07 Jun 2016 15:44:06 GMT

And anothe approach with DO Until:

data list;
   snapshot = input("&strte.",yymmn6.);
   do until (snapshot > input("&ende",yymmn6.));
      output;
      snapshot= intnx('month',snapshot,1);
   end;
   format snapshot yymmn6.;
run;

Exercise for the interested reader to modify to a DO WHILE loop.