topic How to read non delimeted text file in sas ? in SAS Programming

How to read non delimeted file ?

Attyslogin — Mon, 06 Jun 2016 07:25:14 GMT

warm greetings to all.

Can anyone help tell me how to read a text file with following format if there are 3 varibles: name age & city.

Text file :

Rocky26network

Rosy54paris

Alberter28Portugal

version im using is latest university edition !

Thanks & Regards
Atul

How to read non delimeted text file in sas ?

Attyslogin — Mon, 06 Jun 2016 07:19:09 GMT

warm greetings to all.

Can anyone help tell me how to read a text file with following format if there are 3 varibles: name age & city.

Text file :

Rocky26network

Rosy54paris

Alberter28Portugal

Thanks & Regards
Atul

Betreff: How to read non delimeted file ?

andreas_lds — Mon, 06 Jun 2016 07:53:31 GMT

This is a very ugly data-format, but can be handled by using a regular expression:

data want;
   length rx 8
      Name $ 20 
      Age 8 
      City $ 100
   ;
   retain rx;
   drop rx;

   if _n_ = 1 then do;
      rx = prxparse('/([a-z]+)(\d+)([a-z]+)/i');
   end;
   

   input;

   if prxmatch(rx, trim(_infile_)) then do;
      Name = prxposn(rx, 1, trim(_infile_));
      Age = input(prxposn(rx, 2, trim(_infile_)), best.);
      City = prxposn(rx, 3, trim(_infile_));
   end;
   

datalines;
Rocky26network
Rosy54paris
Alberter28Portugal
;
run;

Re: How to read non delimeted file ?

Ksharp — Mon, 06 Jun 2016 08:03:58 GMT

data want;
length Name City $ 80;
input;
      Name = scan(_infile_,1,,'ka');
      Age = input(scan(_infile_,1,,'kd'), best.);
      City = scan(_infile_,2,,'ka');
datalines;
Rocky26network
Rosy54paris
Alberter28Portugal
;
run;

Re: How to read non delimeted file ?

RW9 — Mon, 06 Jun 2016 09:22:49 GMT

You may want to consider why the data is in that format in the first place, it isn't a good setup for a variety of reasons.