topic Re: finding frequency of a specific drug two per id in SAS Programming

finding frequency of a specific drug two per id

lillymaginta — Fri, 29 Apr 2016 16:20:33 GMT

Hi ALl,

I have the following database

id  drug_date drug 
1   1/1/2005   a       
1   1/1/2006  a        
1   2/2/2007  b        
1   3/3/2008  c 
1  3/4/2008   c
1  1/1/2004  a
1  2/2/2005   a
2  5/5/2009   a
2  6/6/2009  a
3  7/7/2007  b


I want the frequency of drugs per id, where each id is required to have the drug dispensed two times. For example id 1: had 4 dates for drug a. Count this as 1 since I need to dates for a per id.
for id 1, don't count b because the id has only one date for b.
For id 1, count c 1 since the id has two dates for c and so on. 
My output will be:
a 2 
b 0
c 1

Re: finding frequency of a specific drug two per id

stat_sas — Fri, 29 Apr 2016 17:28:29 GMT

proc sql;
select drug,sum(count) as count from (
select drug,count(distinct drug) as count from have
group by id,drug
having count(drug)>1)
group by drug;
quit;

Re: finding frequency of a specific drug two per id

PGStats — Fri, 29 Apr 2016 18:41:12 GMT

Your request translated into SQL:

proc sql;
create table want as
select 
    drug, 
    sum(rep>=2) as nbId
from
    (   select drug, id, count(*) as rep 
        from have group by drug, id       )
group by drug;
select * from want;
quit;

Re: finding frequency of a specific drug two per id

PGStats — Fri, 29 Apr 2016 18:48:00 GMT

@stat_sas, using a having clause eliminates drugs that were never prescribed twice (such as "b" here) from the output.

Re: finding frequency of a specific drug two per id

Ksharp — Sat, 30 Apr 2016 02:46:36 GMT

I am not sure I understand your requirement completely .

data have;
input id  drug_date : $20. drug $;
cards;
1   1/1/2005   a       
1   1/1/2006  a        
1   2/2/2007  b        
1   3/3/2008  c 
1  3/4/2008   c
1  1/1/2004  a
1  2/2/2005   a
2  5/5/2009   a
2  6/6/2009  a
3  7/7/2007  b
;
run;
proc summary data=have;
by id drug notsorted;
output out=temp;
run;
data temp;
 set temp;
 count=ifn(_freq_=1,0,1);
run;
proc summary data=temp nway;
class id drug ;
var count;
output out=want(drop=_:) sum=;
run;

Re: finding frequency of a specific drug two per id

lillymaginta — Mon, 02 May 2016 15:22:11 GMT

Thank you all for posting suggestions!