topic Re: Rename all variables by adding a term at the end in SAS Programming

Rename all variables by adding a term at the end

hhchenfx — Sat, 09 Jan 2016 01:15:09 GMT

Hi Everyone,

I have 2 dataset that have similar variables. One file is for daily and the other file is for monthly.

I want to add a term say "_daily" after all variables in daily file and "_monthly" for those in monthly file.

Is there any way to do so instead of using the rename one by one?

Thank you.

data have;
input time var1x var3;
datalines;
1 1 1
2 3 5
1 2 3
;
run;

Re: Rename all variables by adding a term at the end

Tom — Sat, 09 Jan 2016 01:25:22 GMT

Use metadata (SASHELP.VCOLUMN or DICTIONARY.COLUMNS or output of PROC CONTENTS) to generate the rename code.

proc sql noprint ;
  select catx('=',name,cats(name,'_monthly'))
    into :monthly separated by ' '
    from dictionary.columns
    where libname='WORK'
      and memname='MONTHLY'
  ;
quit;
data want ;
   set monthly (rename=(&monthly)) ;
run;

Re: Rename all variables by adding a term at the end

Reeza — Sat, 09 Jan 2016 02:37:35 GMT

Slight modification to Tom's code - I would suggest using proc datasets to modify the variable names instead.

If you're merging the files though, do it in that step instead of a separate rename step.

Re: Rename all variables by adding a term at the end

Ksharp — Mon, 11 Jan 2016 05:31:06 GMT

data have;
input time var1x var3;
datalines;
1 1 1
2 3 5
1 2 3
;
run;


data _null_;
 set sashelp.vcolumn(where=(libname='WORK' and memname='HAVE') keep=libname memname name) end=last;
 if _n_ eq 1 then call execute('proc datasets library=work nolist nodetails;modify have;rename');
 call execute(cats(name,'=',name,'_daily'));
 if last then call execute(';quit;');
run;

Re: Rename all variables by adding a term at the end

AZIQ1 — Thu, 17 Mar 2016 19:22:03 GMT

Hi,

I used this code and it worked successfully. But before this step I want to remove "_" from all my variable names - is there a quick way? I tried using compress with your code but failed.

Thank you.

Re: Rename all variables by adding a term at the end

Tom — Thu, 17 Mar 2016 19:27:58 GMT

The same steps should apply. Try just running the part that calculates the new variable name from the old name in a data step so you can look at the result and figure what is happening.

new_name = compress(name,'_');

Re: Rename all variables by adding a term at the end

AZIQ1 — Thu, 17 Mar 2016 19:32:57 GMT

Thank you, now need a step to keep the ones without '_' as is. My data has a mix of vars with '_' and some without.

Re: Rename all variables by adding a term at the end

Ksharp — Fri, 18 Mar 2016 00:49:23 GMT

if not findc(name,'_') then  call execute(cats(name,'=',name,'_daily'));

Re: Rename all variables by adding a term at the end

AZIQ1 — Thu, 14 Apr 2016 20:28:07 GMT

Thank you can I apply the same logic or code to change the labels for all my variables - i mean i want to add a term before the label name for all vars:

something like this:

PROC CONTENTS DATA=sat1 OUT=tmp_sat2;
RUN;
data _null_;
set WORK.tmp_SAT2(where=(libname='WORK' and memname='SAT1') keep=libname memname label) end=last;
if _n_ eq 1 then call execute('proc datasets library=work nolist nodetails;modify SAT1;LABEL');
call execute(cats(label,'=','SAT_',label));
if last then call execute(';quit;');
run;

Your feedback is highly appreciated

Re: Rename all variables by adding a term at the end

Ksharp — Fri, 15 Apr 2016 04:44:46 GMT

Sure. Your code looks good .

Re: Rename all variables by adding a term at the end

AZIQ1 — Fri, 15 Apr 2016 21:33:16 GMT

Hi,

Its giving me errors - Variable not found!

Help

Re: Rename all variables by adding a term at the end

Ksharp — Sat, 16 Apr 2016 03:01:34 GMT

Can you post the content of table tmp_SAT2 , and in call execute(cats(label,'=','SAT_',label)); you use the same variable name at the both side, That doesn't look right.