topic Re: Exporting datafile with macro adds (unwanted) extra blanks in SAS Programming

Exporting datafile with macro adds (unwanted) extra blanks

bballvas — Thu, 07 Jul 2011 23:18:32 GMT

This code is the last part of my macro:

proc export data = allperiods

outfile = "g/entitysheets/test&entityname..csv"

dbms = csv replace;

run;

The data is exported correctly, except I'd like the name to be (for example) testEntityX.csv. But what I'm getting is testEntityX .csv. How can I get rid of those spaces without going through and deleting them manually?

Thanks for the help!

Re: Exporting datafile with macro adds (unwanted) extra blanks

art297 — Thu, 07 Jul 2011 23:38:33 GMT

How about if you use the strip or right function to get rid of the extra spaces? Of course, dependent on your code, you may have to wrap the function in a %sysfunc().

Art

Re: Exporting datafile with macro adds (unwanted) extra blanks

bballvas — Thu, 07 Jul 2011 23:58:24 GMT

I was looking into the strip function, but wasn't sure how I would use it on the file name (I'm new to SAS). Would I just say outfile = strip("g/entitysheets/test&entityname..csv")?

Re: Exporting datafile with macro adds (unwanted) extra blanks

art297 — Fri, 08 Jul 2011 03:26:50 GMT

If spaces at the end of your macro variable are really the problem, you could progbably use it like:

g:\entitysheets\%sysfunc(strip(&entityname.)).csv

Art

Exporting datafile with macro adds (unwanted) extra blanks

DF — Fri, 08 Jul 2011 08:19:16 GMT

Not too different that Art's suggestion, but there's also the %trim() macro function:

data _null_;

format var $20.;

var = 'file_20110708';

call symput('var',var);

run;

%put &var.;

%put filename is "c:\&var..csv";

%put filename is "c:\%trim(&var.).csv";

Exporting datafile with macro adds (unwanted) extra blanks

andreas_lds — Fri, 08 Jul 2011 11:14:47 GMT

You can add %let entityname = &entityname; right before proc export and all the blanks are gone.

Exporting datafile with macro adds (unwanted) extra blanks

bballvas — Fri, 08 Jul 2011 13:25:10 GMT

Thanks for all the help!

Exporting datafile with macro adds (unwanted) extra blanks

data_null__ — Fri, 08 Jul 2011 13:45:54 GMT

Everyone has suggested ways to FIX the problem after the fact. You may want to reflect on how the value was created and address the issue there. I suspect you created the value with CALL SYMPUT. SYMPUT does not trim the value of its arguments. You could use STRIP or TRIM with SYMPUT or use SYMPUTX a new version of SYMPUT that does STRIP the value of its arguments. SYMPUTX also quietly converts numeric to character, and has a third parameter for SCOPE.

data _null_;

call symputX('nx',_n_);

call symput('n',_n_);

run;

%put NOTE: **&N** **&nx**;